summaryrefslogtreecommitdiff
path: root/libmailutils/tests/lock.at
blob: 0886390b94beac7c784af9edc5c58d5416b92f2a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
# This file is part of GNU Mailutils. -*- Autotest -*-
# Copyright (C) 2010-2021 Free Software Foundation, Inc.
#
# GNU Mailutils is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; either version 3, or (at
# your option) any later version.
#
# GNU Mailutils is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with GNU Mailutils.  If not, see <http://www.gnu.org/licenses/>.

AT_BANNER([Locking])

m4_pushdef([LCK_TEST],[
AT_SETUP([$1])
AT_KEYWORDS([lock])
AT_CHECK([touch file
lck $2 file
],
m4_shift2($@))
AT_CLEANUP
])

# Child holds lock for 4 seconds, master acquires it when child has
# released it.
LCK_TEST([retries], [--hold=4 --retry=10 --delay=1])

# Child holds lock for 4 seconds, master does two retries with one
# second interval and finishes before being able to acquire it.
LCK_TEST([conflict with previous locker], [--hold=4 --retry=2 --delay=1],
         [1],[],
	 [lck: mu_locker_lock() failed: Conflict with previous locker
])

# Child abandons the lock; master is not able to acquire it.
LCK_TEST([abandoned lock], [--abandon --retry=4 --delay=1],
         [1],[],
	 [lck: mu_locker_lock() failed: Conflict with previous locker
])

# Child abandons the lock; master asserts that its pid is not active and
# acquires it.
LCK_TEST([PID check],[--pid-check --abandon --retry=4 --delay=1])

# Child abandons the lock; master waits until it has expired and acquires
# it.
LCK_TEST([lock expiration],
         [--abandon --expire=3 --retry=10 --delay=1])


# Default settings correspond to --retry=10 --delay=1 --expire=600
LCK_TEST([default settings], [--hold=2])

m4_popdef([LCK_TEST])

Return to:

Send suggestions and report system problems to the System administrator.