dnl This file is part of Gamma
dnl Copyright (C) 2002-2018 Sergey Poznyakoff
dnl
dnl Gamma is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 3, or (at your option)
dnl any later version.
dnl
dnl Gamma is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with Gamma.  If not, see <http://www.gnu.org/licenses/>.

AC_PREREQ(2.63)

AC_INIT(gamma, [2.0.90], [gray+gamma@gnu.org.ua])
AC_CONFIG_SRCDIR(gamma/guile-sql.h)
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AC_CANONICAL_SYSTEM
AM_INIT_AUTOMAKE([1.11.1 gnu tar-ustar readme-alpha silent-rules])
AC_CONFIG_HEADERS([config.h])

# Enable silent rules by default:
AM_SILENT_RULES([yes])

dnl Checks for programs.
AC_PROG_AWK
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AM_PROG_LIBTOOL

GINT_INIT(gint,[2.2.0])

AC_SUBST(INCLUDEPATH)
AC_MSG_CHECKING(for additional includes)
AC_ARG_WITH([include-path],
            AC_HELP_STRING([--with-include-path=PATH],
	                   [specify additional include paths; PATH is a ':' separated list of directories]),
	    [ for path in `echo $withval | sed 's/:/ /g'`
              do
                INCLUDEPATH="$INCLUDEPATH -I$path"
              done])
AC_MSG_RESULT($INCLUDEPATH)

AC_MSG_CHECKING(for additional libraries)
AC_ARG_WITH([lib-path],    
	    AC_HELP_STRING([--with-lib-path=PATH],
                           [specify additional library paths]),
	    [ for path in `echo $withval | sed 's/:/ /g'`
              do
                LIBS="$LIBS -L$path"
              done])
AC_MSG_RESULT($LIBS)

dnl Checks for library functions.
AC_HEADER_STDC

dnl Modules

gamma_MODCONFIG

if test -z "$GAMMA_LIB_LIST"; then
  AC_MSG_ERROR([Nothing to build!])
fi

# Doc hints.
# Select a rendition level:
#  DISTRIB for stable releases (at most one dot in the version number)
#  and maintenance releases (two dots, patchlevel < 50)
#  PROOF for alpha releases.
#  PUBLISH can only be required manually when running make in doc/
AC_SUBST(RENDITION)
case `echo $VERSION|sed  's/[[^.]]//g'` in
""|".")  RENDITION=DISTRIB;;
"..")  if test `echo $VERSION | sed  's/.*\.//'` -lt 50; then
	 RENDITION=DISTRIB
       else
         RENDITION=PROOF
       fi;;
*)     RENDITION=PROOF;;
esac
  
if test $RENDITION = "PROOF"; then
  if test -r $srcdir/git-describe; then
    GIT_DESCRIBE=`sed '2,$d' $srcdir/git-describe`
    AC_DEFINE_UNQUOTED([GIT_DESCRIBE], "$GIT_DESCRIBE",
                       [The most recent git tag])
  fi
fi


AC_CONFIG_FILES(Makefile
                gint/Makefile
                gamma/Makefile
		scripts/Makefile
		examples/Makefile
		doc/Makefile)

AC_OUTPUT