aboutsummaryrefslogtreecommitdiff
path: root/lib/App/Acmeman/Source/File.pm
blob: c622d518a0a78217539b5281e19831e2cd6af137 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
package App::Acmeman::Source::File;

use strict;
use warnings;
use Carp;
use File::Spec;
use parent 'App::Acmeman::Source';
use Getopt::Long qw(GetOptionsFromArray :config gnu_getopt no_ignore_case);
use App::Acmeman::Log qw(:all);

sub new {
    my $class = shift;
    my $pattern = shift || croak "file name or globbing pattern must be given";
    my $ignore = '^\.|~$|\.bak$|^#.*#$';
    my $host;
    GetOptionsFromArray(\@_,
			'ignore|i=s' => \$ignore,
			'host|h=s' => \$host);
    unless ($pattern =~ m{[][*?]}) {
	$pattern =~ s{/$}{};
	if (-d $pattern) {
	    $pattern = File::Spec->catfile($pattern, '*');
	}
    }
    bless { pattern => $pattern,
	    ignore => $ignore,
	    host => $host }, $class;
}

sub scan {
    my ($self) = @_;
    debug(1, "initializing file list from $self->{pattern}");
    my $err = 0;
    if ($self->{host}) {
	$self->define_domain($self->{host});
    }
    foreach my $file (glob $self->{pattern}) {
	next if $file =~ m{$self->{ignore}};
	$err |= $self->load($file);
    }
    return $err == 0;
}

sub load {
    my ($self, $file) = @_;
    debug(1, "reading $file");
    open(my $fh, '<', $file)
	or do {
	    error("can't open $file: $!");
	    return 0;
        };
    chomp(my @lines = <$fh>);
    close $fh;
    if (@lines) {
	if ($self->{host}) {
	    $self->define_alias($self->{host}, @lines);
        } else {
	    my $cn = shift @lines;
	    $self->define_domain($cn);
	    $self->define_alias($cn, @lines);
	}
    }
    return 1;
}

1;

    

Return to:

Send suggestions and report system problems to the System administrator.