summaryrefslogtreecommitdiffabout
path: root/configure.ac
blob: af72e65fa8de758c30fd4bb66bab26b614aa12c5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
# This file is part of Varnish-mib -*- autoconf -*-
# Copyright (C) 2014-2019 Sergey Poznyakoff
#
# Varnish-mib is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3, or (at your option)
# any later version.
#
# Varnish-mib is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with Varnish-mib.  If not, see <http://www.gnu.org/licenses/>.

AC_PREREQ(2.69)
AC_INIT([varnish-mib], 3.99.90, [gray@gnu.org])
AC_CONFIG_SRCDIR(src/varnish_mib.mib2c)
AM_CONFIG_HEADER(config.h)
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_SYSTEM
AC_LANG(C)
AM_INIT_AUTOMAKE([gnu tar-ustar silent-rules])
AM_SILENT_RULES([yes])

AC_GNU_SOURCE
AC_PROG_CC
AC_PROG_CC_STDC
if test "x$ac_cv_prog_cc_c99" = xno; then
  AC_MSG_ERROR([could not find a C99 compatible compiler])
fi
AC_PROG_CPP
AM_PROG_LEX

AC_PROG_INSTALL
AC_PROG_LIBTOOL
AC_PROG_MAKE_SET

# Check for pkg-config
PKG_PROG_PKG_CONFIG

# Checks for Varnish
PKG_CHECK_MODULES([VARNISHAPI], [varnishapi >= 5.2.1])

# Check for Net-SNMP
AC_PATH_PROG([NET_SNMP_CONFIG], net-snmp-config, none, $PATH)
if test "$NET_SNMP_CONFIG" = "none"; then
  AC_MSG_ERROR([cannot find Net-SNMP (net-snmp-config not found)])
fi

AC_SUBST(NET_SNMP_LIBS, `$NET_SNMP_CONFIG --agent-libs`)
AC_SUBST(NET_SNMP_EXLIBS, `$NET_SNMP_CONFIG --external-libs`)
AC_SUBST(NET_SNMP_MIBDIRS, `$NET_SNMP_CONFIG --mibdirs`)
AC_SUBST(NET_SNMP_MIBS, `$NET_SNMP_CONFIG --default-mibs`)

# Checks for header files.
AC_HEADER_STDC

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_SIZE_T

# Directories
AC_SUBST([DLMODDIR],['$(libdir)/snmp'])
AC_ARG_WITH([dlmoddir],
 [AC_HELP_STRING([--with-dlmoddir=DIR],
                 [installation directory for net-snmp loadable agents])],
 [case $withval in
  /*) DLMODDIR=$withval;;
  *)  AC_MSG_ERROR([argument to --with-dlmoddir must be absolute pathname])
  esac])

AC_SUBST([MIBDIR],['$(datarootdir)/snmp/mibs'])
AC_ARG_WITH([mibdir],
 [AC_HELP_STRING([--with-mibdir=DIR],
                 [installation directory for MIB files])],
 [case $withval in
  /*) MIBDIR=$withval;;
  *)  AC_MSG_ERROR([argument to --with-mibdir must be absolute pathname])
  esac])

  
# Generate output
AC_CONFIG_FILES([
    Makefile
    src/Makefile
])
AC_OUTPUT

Return to:

Send suggestions and report system problems to the System administrator.