From 6f20d264a2095120dd197c1592bc99064ba504cf Mon Sep 17 00:00:00 2001
From: Sergey Poznyakoff <gray@gnu.org.ua>
Date: Wed, 19 Nov 2014 02:05:44 +0200
Subject: Add missing files.

---
 git2chg.awk | 75 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)
 create mode 100644 git2chg.awk

diff --git a/git2chg.awk b/git2chg.awk
new file mode 100644
index 0000000..6dad87e
--- /dev/null
+++ b/git2chg.awk
@@ -0,0 +1,75 @@
+# This file is part of grecs
+# Copyright (C) 2007-2014 Sergey Poznyakoff
+#
+# Grecs is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3, or (at your option)
+# any later version.
+#
+# Grecs is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with Grecs.  If not, see <http://www.gnu.org/licenses/>.
+
+BEGIN {
+  if (since)
+    split(since,since_a,"-")
+}
+
+function timeok(t,   a) {
+	if (!since)
+		return 1
+	split(t,a,"-")
+	if (a[1] < since_a[1])
+		return 0
+	if (a[1] > since_a[1])
+		return 1
+	if (a[2] < since_a[2])
+		return 0
+	if (a[2] > since_a[2])
+		return 1
+	return a[3] > since_a[3]
+}
+      
+/^[0-9]+ .* +<[^>]+>/ {
+	s = strftime("%F", $1)
+	if (!timeok(s))
+	  exit
+	sub(/^[0-9]+ +/,"")
+	if (s == datestr && author == $0)
+		next
+	datestr = s
+	author = $0
+	if (runlen) { runlen = 0; print "" }
+	printf("%s  %s\n", datestr, author)
+	next
+}
+/^Signed-off-by:/ { next }
+/^<unknown>$/ { next }
+NF==0 {
+	runlen++
+	next
+}
+{ if (runlen) { runlen = 0; print "" }
+  print "\t" $0 }
+
+END {
+	if (append) {
+		print ""
+		while ((getline < append) > 0) {
+			if (match($0, /^Local *Variables:/))
+				break
+			print
+		}
+	}
+	print "\f"
+	# Make sure Emacs won't recognize this line:
+	print "Local", "Variables:"
+	print "mode: change-log"
+	print "version-control: never"
+	print "buffer-read-only: t"
+	print "End:"
+}
-- 
cgit v1.2.1