aboutsummaryrefslogtreecommitdiff
path: root/src/html.lex.l
blob: 0e0d4238078abd1265d773a9ad20a20ad9949eb4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
%{
/* This file is part of tagr.
   Copyright (C) 2000, 2005, 2006, 2009 Max Bouglacoff, Sergey Poznyakoff

   This program is free software; you can redistribute it and/or modify
   it under the terms of the GNU General Public License as published by
   the Free Software Foundation; either version 3, or (at your option)
   any later version.

   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License
   along with this program.  If not, see <http://www.gnu.org/licenses/>. */

#ifdef HAVE_CONFIG_H
# include <config.h>
#endif

#include <stdlib.h>
#include <stdio.h>
#include <string.h>
#include <errno.h>	
#include <tagr.h>
#include <html.gram.h>

char *html_input_file;
int html_input_line;
%}

%s EVAL

NAME [A-Za-z_][A-Za-z0-9_]*
N [0-9]+

%%
\$\$	{
	yylval.character = '$';
        return CHAR;
}
\${NAME}        {
        if (find_value (yytext+1, &yylval.value))
	  {
	    yyerror (_("unknown identifier"));
	    init_value (&yylval.value, unspecified_value, NULL);
	  }
	return IDENT;
}
\$\({NAME}\)      {
	yytext[yyleng-1] = 0;
	if (find_value (yytext+2, &yylval.value))
	  {
	    yyerror (_("unknown identifier"));
	    init_value (&yylval.value, unspecified_value, NULL);
	  }
	return IDENT;
}
\$\({NAME}:{N}\)  {
	char *p = strchr (yytext, ':');
	*p = 0;
	if (find_value (yytext+2, &yylval.value))
	  {
	    yyerror (_("unknown identifier"));
	    init_value (&yylval.value, unspecified_value, NULL);
	  }
	else
	  {
	    yylval.value.prec = strtoul (p+1, NULL, 10);
	  }
	return IDENT;
}
\$\({NAME}:[^)]+\)  {
        pp_value_t val;
        char *p = strchr (yytext, ':');
	*p++ = 0;
	if (find_value (yytext+2, &val))
	  {
	    yyerror (_("unknown identifier"));
	    init_value (&yylval.value, unspecified_value, NULL);
	  }
	else
	  {
	    size_t len = strlen (p) - 1;
	    init_value (&yylval.value, val.type, &val.v);
	    yylval.value.prec = val.prec;
	    yylval.value.format = val.format;
	    yylval.value.fmt = xmalloc (len + 1);
	    memcpy (yylval.value.fmt, p, len);
	    yylval.value.fmt[len] = 0;
	  }
	return IDENT;
}
\$\{            return OBRACE;
\$\}            return CBRACE;
<EVAL>[ \t]+    ;
<EVAL>"("|")"|"+"|"-"|"*"|"/"  return yytext[0];
<EVAL>{N}\.?([eE][-+]?{N}+)? {
         yylval.number = strtod (yytext, NULL);
	return NUMBER;
}
\n              {
	html_input_line++;
	yylval.character = yytext[0];
	return CHAR;
}
.               {
	yylval.character = yytext[0];
	return CHAR;
}

%%

void
begin_eval ()
{
  BEGIN (EVAL);
}

void
end_eval ()
{
  BEGIN (INITIAL);
}

int
html_open (char *file)
{
  yyin = fopen (file, "r");
  if (!yyin)
    {
      logmsg (L_ERR, _("cannot open input file `%s': %s"),
	     file, strerror (errno));
      return 1;
    }
  html_input_file = file;
  html_input_line = 1;
  return 0;
}

void
html_close ()
{
  if (yyin)
    {
      fclose (yyin);
      yyin = NULL;
    }
}

int
yywrap ()
{
  html_close ();
  return 1;
}
		

Return to:

Send suggestions and report system problems to the System administrator.