summaryrefslogtreecommitdiff
path: root/lib/SlackBuilder.pm
blob: bf792bf4fea92bf6aae611b81a7a87cce0fb99cd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
package SlackBuilder;
use strict;
use warnings;
use Carp;
use SlackBuild::Config;
use SlackBuild::URI;
use SlackBuild::Archive;
use SlackBuild::Registry;
use SlackBuild::Request;
use SlackBuild::Rc;
use SlackBuild::Counter;
use File::Spec;
use File::Basename;
use File::Temp qw/ tempfile tempdir /;
use File::Copy;
use POSIX::Run::Capture qw(:all);
use POSIX qw(:sys_wait_h strerror uname);
use Log::Log4perl qw(:levels);
use Try::Tiny;
use Carp;

use constant {
    E_OK => 0,
    E_SYNTAX => 1,
    E_EXEC => 2,
    E_BADBUILD => 3,
    E_FAIL => 4
};

our $VERSION = '1.0';
our @EXPORT = qw(E_OK
                 E_SYNTAX
                 E_EXEC
                 E_BADBUILD
                 E_FAIL);

sub new {
    my ($class, %args) = @_;
    my $self = bless {}, $class;

    $self->{conf} = new SlackBuild::Config(
	filename => $ENV{SLACKBUILDER_CONFIG} || '/etc/slackbuilder.conf');

    Log::Log4perl::Layout::PatternLayout::add_global_cspec('N',
	 sub {
	     my ($layout, $message, $category, $priority, $caller_level) = @_;
	     my $pfx = "$0: $priority";
	     if ($priority eq 'DEBUG') {
		 $pfx .= ": $category";
		 if ($self->conf->tree->Core->Verbose->value > 1) {
		     my $caller_offset = Log::Log4perl::caller_depth_offset($caller_level);
		     my ($package,$filename,$line) = caller($caller_offset);
		     $pfx .= ": $filename:$line";
		 }
	     }
	     return $pfx;
	 });
    $self->logger->level($INFO);
    my $layout = new Log::Log4perl::Layout::PatternLayout("%N: %m%n");
    my $appender = new Log::Log4perl::Appender('Log::Dispatch::Screen',
					       stderr => 1);
    $appender->layout($layout);
    $self->logger->add_appender($appender);
    my $v;
    if (defined($v = $self->conf->tree->Core->Logging->value) && -f $v) {
	Log::Log4perl::init($v);
    }
    
    if ($v = delete $args{verbose}) {
	$self->conf->set(qw(core verbose), $v);
    }
    if ($self->conf->tree->Core->Verbose->value) {
	$self->logger->level($DEBUG);
    }

    if ($v = delete $args{image}) {
	$self->conf->set(qw(core image), $v);
    }

#    croak "bad number of arguments" if keys(%args);

    $self->clear;

    return $self;
}

sub conf { shift->{conf} }

sub rootdir  { shift->conf->tree->Dir->Root->value };
sub spooldir { shift->conf->tree->Dir->Spool->value };
sub tmpdir   { shift->conf->tree->Dir->Tmp->value };
sub logdir   { shift->conf->tree->Dir->Log->value };
sub pkgdir   { shift->conf->tree->Dir->Pkg->value };
sub ospkgdir {
    my $self = shift;
    File::Spec->catfile($self->pkgdir, $self->osversion, @_);
}
sub image    { shift->conf->tree->Core->Image->value };
sub arch     { shift->{_arch} };

sub logger { shift->{_logger} //= Log::Log4perl::get_logger('SlackBuild') }

sub error {
    my ($self, $diag) = @_;
    $self->logger->error($diag);
}

sub errno {
    my $self = shift;
    croak "bad number of arguments" if @_ > 1;
    if (my $v = shift) {
	$self->{_errno} = $v;
    }
    return $self->{_errno};
}

sub errors { shift->{_error_counter} //= new SlackBuild::Counter }

sub is_success {
    shift->errno == E_OK;
}

sub clear {
    my $self = shift;
    $self->{_errno} = E_OK;
    $self->errors->clear();
    delete $self->{_request};
    delete $self->{_result};
}

sub request {
    my $self = shift;
    croak "too many arguments" if @_ > 1;
    if (my $v = shift) {
	$self->{_request} = $v;
    }
    return $self->{_request};
}

sub package_name { shift->request->package }
sub package_version { shift->request->version }
sub package_build { shift->request->build }
sub rc { shift->request->rc }
sub slackbuild_uri { shift->request->slackbuild_uri }
sub source_uri { shift->request->source_uri }
sub prereq { shift->request->prereq || []}

sub environ {
    my $self = shift;
    my $env = {%{$self->request->environ // {}},
	       VERSION => $self->package_version};
    if (my $b = $self->package_build) {
	$env->{BUILD} = $b;
    }
    return $env;
}

sub file {
    my ($self, $name) = @_;
    my $src = File::Spec->catfile($self->tmpdir, $name);
    my $dst = $self->ospkgdir($name);

    my $dstdir = dirname($dst);
    if (! -d $dstdir) {
	unless (mkdir($dstdir)) {
	    $self->error("mkdir($dstdir): $!");
	    $self->errno(E_FAIL);
	    return;
	}
    }
    
    if (-e $dst) {
	unlink $dst;
    }
    unless (move($src, $dst)) {
	$self->error("move($src, $dst): $!");
	$self->errno(E_FAIL);
    }
    push @{$self->{_result}{output_files}}, $dst;
}

sub os_probe {
    my $self = shift;

    unless (exists($self->{_os_release})) {
	my @args = ( 'docker',
		     'run',
		     '--rm=true',
		     $self->image,
		     '/bin/sh',
		     '-c',
		     'uname -m; cat /etc/os-release' );

	my $obj = new POSIX::Run::Capture(argv => \@args);
	if ($obj->run) {
	    $self->_runcap_diag($obj);
	} else {
	    $self->error("can't run docker: ".strerror($obj->errno));
	    return $self->errno(E_EXEC);
	}
	$obj->rewind(SD_STDOUT);
	chomp($self->{_arch} = $obj->next_line(SD_STDOUT));
	while (my $s = $obj->next_line(SD_STDOUT)) {
	    chomp($s);
	    my ($name,$value)=split /=/, $s, 2;
	    $value =~ s/^"(.*)"\s*$/$1/;
	    $self->{_os}{$name} = $value;
	}

	if (my $name = $self->os_release('NAME')) {
	    if ($name ne 'Slackware') {
		$self->error('image '
			     . $self->image
			     . " is not a Slackware image (reported name: $name)");
		return $self->errno(E_FAIL);
	    }
	} else {
	    $self->error("can't determine distribution name");
	    return $self->errno(E_FAIL);
	}
	unless ($self->os_release('VERSION')) {
	    $self->error("can't determine Slackware version");
	    return $self->errno(E_FAIL);
	}
    }
    return E_OK;
}

sub os_release {
    my ($self, $value) = @_;
    return $self->{_os}{$value};
}

sub osversion { shift->os_release('VERSION') }

sub output_files {
    my $self = shift;
    $self->{_result}{output_files} //= [];
    if (wantarray) {
	return () if $self->errno;
	return (@{$self->{_result}{output_files}});
    } else {
	return @{$self->{_result}{output_files}};
    }
}

sub wd {
    my $self = shift;
    unless ($self->{_wd}) {
	$self->{_wd} = tempdir(DIR => $self->spooldir, CLEANUP => 1);
    }
    return $self->{_wd};
}

sub slackbuild_name {
    my $self = shift;
    return $self->package_name . '.SlackBuild';
}

sub run {
    my ($self, $req) = @_;

    $self->clear;

    if (!ref($req)) {
	my $name = $req;
	$req = try {
	    new SlackBuild::Request($name)
	} catch {
	    my $err = (split /\n/)[0];
	    $err =~ s{\s+at .* line \d+\.$}{};
	    $self->error("$name: $err");
	    undef
        };
	return $self->errno(E_SYNTAX) unless $req;
    }
    
    unless ($req->package) {
	$self->error("package: not present in request");
    }
    unless ($req->slackbuild_uri) {
	$self->error("slackbuild_uri: not present in request");
    }
    if ($self->errors) {
	return $self->errno(E_SYNTAX);
    }
    
    $self->request($req);

    my $archive = new SlackBuild::Archive($self->package_name,
					  $self->slackbuild_uri);

    return $self->errno(E_FAIL)
	unless $archive->download($self->wd);

    $self->os_probe;
    return $self->errno if $self->errno;
    
    $self->request->addinfo($archive->info->for_arch($self->arch));

    if (my $urilist = $self->request->source_uri) {
	foreach my $s (@$urilist) {
	    my $uri = new SlackBuild::URI($s);
	    my $dest = File::Spec->catfile($self->wd,
			  $self->request->extract_local_name($uri->as_string));
	    return $self->errno(E_FAIL)
		unless $uri->download($dest);
	}
    }
	
    return $self->_build;
}  

sub _runcap_diag {
    my ($self, $obj) = @_;
    if (WIFEXITED($obj->status)) {
	return if $obj->status == 0;
	while (my $s = $obj->next_line(SD_STDERR)) {
	    chomp($s);
	    $self->error($s);
	}
	$self->error("program "
		     . $obj->program
		     . " terminated with code "
		     . WEXITSTATUS($obj->status));
    } elsif (WIFSIGNALED($obj->status)) {
	$self->error("program "
		     . $obj->program
		     . " terminated on signal "
		     . WTERMSIG($obj->status));
    } else {
	$self->error("program "
		     . $obj->program
		     . " terminated with unrecogized code "
		     . $obj->status);
    }
    $self->errno(E_EXEC);
}
 
sub _logfilename {
    my $self = shift;
    return File::Spec->catfile($self->logdir, $self->package_name . '.log');
}

sub _prepare {
    my $self = shift;
    
    # Find prerequisites
    # FIXME: Build a dependency graph and spawn slackbuilders for missing ones

    # FIXME: registry type should be configurable
    my $reg = new SlackBuild::Registry('FS', dir => $self->ospkgdir);

    my $filename = File::Spec->catfile($self->wd, 'rc');
    return unless SlackBuild::Rc->new($self)->write($reg, $filename);
    return 'rc';
}

# Regex created using the following command:
# (find / -type d -not -name '/' -mindepth 1 -maxdepth 1 -printf '%f\n';
#  echo '.';
#  echo 'install') | xargs regexp-opt --pcre
my $file_name_rx = q{(?:b(?:in|oot)|dev|etc|home|install|l(?:ib(?:64)?|ost\+found)|m(?:edia|nt)|opt|proc|r(?:oot|un)|s(?:bin|rv|ys)|tmp|(?:us|va)r|\.)(?:/\w+)*};

# Parser states:
use constant {
    ST_INIT     => 0,  # Initial state
                       # [expect OUT]  "Creating Slackware package: foobar"
                       #         goto ST_CREATING
    ST_CREATING => 1,  # [expect OUT]  Empty line
                       #         goto ST_LISTING
                       # [else]  goto ST_BUILT
    ST_LISTING  => 2,  # [expect ERR]  File name (matching $file_name_rx)
                       #         remain in this state
                       # [else]  keep state
                       # [expect OUT]  Empty line
                       #         goto ST_CREATED
                       # [else]  goto ST_BUILT
    ST_CREATED  => 3,  # [expect OUT]  "Slackware package foo created"
	               #         goto ST_BUILT
    ST_BUILT    => 4,  # Essentially same as ST_INIT, except that we
                       # know that the package has been built
};

# state([$newstate])
# With argument - switch to that state.
# Return current state.
sub state {
    my ($self, $newstate) = @_;
    if (defined($newstate)) {
	$self->logger->debug("going to $newstate");
	$self->{_state} = $newstate;
    }
    return $self->{_state};
}

# Parsers for each particular state.
# Each parser is named by the corresponding state, converted to lower case,
# prefixed with underscore and suffixed by the channel name ('_err' or '_out').
# Argument is the line of text obtained from that channel, without trailing
# linefeed character.

sub _st_init_out {
    my ($self, $input) = @_;
    if ($input =~ m{^Creating Slackware package:}) {
	$self->logger->info($input);
	$self->state(ST_CREATING);
    }
}

sub _st_default_err {
    my ($self, $input) = @_;
    $self->errors->more('build');
}

sub _st_built_err {
    my ($self, $input) = @_;
    $self->errors->more('packaging');
}

sub _st_created_out {
    my ($self, $input) = @_;
    if ($input =~ m{^Slackware package /tmp/(.+?) created}) {
	$self->file($1);
	$self->logger->info($input);
	$self->state(ST_BUILT);
    } else {
        $self->logger->error("unexpected output: $input");
	$self->state(ST_INIT);
    }
}

sub _st_creating_out {
    my ($self, $input) = @_;
    if ($input eq '') {
	$self->state(ST_LISTING);
    } else {
	$self->state(ST_BUILT);
    }
}

sub _st_listing_err {
    my ($self, $input) = @_;
    if ($input =~ m{$file_name_rx}) {
	$self->logger->debug("adding file $input");
    } else {
	$self->logger->error($input);
    }
}

sub _st_listing_out {
    my ($self, $input) = @_;
    if ($input eq '') {
	$self->state(ST_CREATED);
    }
}    

# Parser tables bring together parsers for each channel:

my @parser_out = (
    \&_st_init_out,
    \&_st_creating_out,
    \&_st_listing_out,
    \&_st_created_out,
    \&_st_init_out
);

my @parser_err = (
    \&_st_default_err,
    \&_st_default_err,
    \&_st_listing_err,
    \&_st_default_err,
    \&_st_built_err
);    

# Finally, parser functions to be called for each channel:

sub parser_out {
    my ($self, $line) = @_;
    $self->logger->debug("OUT: $line");
    $self->${\$parser_out[$self->state]}($line);
}

sub parser_err {
    my ($self, $line) = @_;
    $self->logger->debug("ERR: $line");
    $self->${\$parser_err[$self->state]}($line);
}

sub _build {
    my $self = shift;
    
    my $contname = $self->package_name . '_slackbuild';
    my $rcfile = $self->_prepare or return $self->errno(E_FAIL);
    my @args = ( 'docker',
		 'run',
		 '--rm=true',
		 '--workdir=/usr/src',
		 '--security-opt=seccomp=unconfined', # This one is needed for Emacs
		 '-v', $self->wd . ':/usr/src',
		 '-v', $self->tmpdir . ':/tmp',
		 '-v', $self->ospkgdir . ':/var/pkg:ro',
		 $self->image,
		 '/bin/sh',
		 $rcfile,
		 $self->slackbuild_name);

    $self->logger->info(
	sprintf("building %s on %s version %s (%s)\n",
		$self->package_name,
		$self->os_release('NAME'),
		$self->os_release('VERSION'),
	        $self->arch));

    open(my $logfd, '>', $self->_logfilename)
	or do {
	    $self->logger->fatal("can't create log file " .
				 $self->_logfilename .
				 ": $!");
	    return $self->errno(E_FAIL);
    };

    $self->state(ST_INIT);
    my $obj = new POSIX::Run::Capture(
	argv => \@args,
	stdout => sub {
	    my $line = shift;
	    print $logfd "OUT: $line";
	    $logfd->flush();
	    chomp($line);
	    $self->parser_out($line);
	},
	stderr => sub {
	    my $line = shift;
	    print $logfd "ERR: $line";
	    $logfd->flush();
	    chomp($line);
	    $self->parser_err($line);
	});
    $self->{_result}{docker} = $obj;
    if ($obj->run) {
	$self->_runcap_diag($obj);
    } else {
	$self->logger->fatal("can't run docker: ".strerror($obj->errno));
	return $self->errno(E_EXEC);
    }
    return $self->errno(E_OK);
}    

1;

Return to:

Send suggestions and report system problems to the System administrator.