summaryrefslogtreecommitdiff
path: root/lib/SlackBuilder.pm
blob: 688a6971b9d003547ffd8b2e95f52a17c8bfef28 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
package SlackBuilder;
use strict;
use warnings;
use Carp;
use SlackBuild::URI;
use SlackBuild::Archive;
use SlackBuild::Registry;
use SlackBuild::Rc;
use File::Spec;
use File::Basename;
use File::Temp qw/ tempfile tempdir /;
use File::Copy;
use POSIX::Run::Capture qw(:all);
use POSIX qw(:sys_wait_h strerror uname);

use constant {
    E_OK => 0,
    E_SYNTAX => 1,
    E_EXEC => 2,
    E_BADBUILD => 3,
    E_FAIL => 4
};

our $VERSION = '1.0';
our @EXPORT = qw(E_OK
                 E_SYNTAX
                 E_EXEC
                 E_BADBUILD
                 E_FAIL);

our $rootdir = "/srv/slackbuild";
our $image = "gray/slackware:14.1-full";

sub new {
    my ($class, %args) = @_;
    my $self = bless {}, $class;

    $self->{_rootdir} = delete $args{rootdir} || $rootdir;
    $self->{_spooldir} = delete $args{spooldir} || "$rootdir/spool";
    $self->{_tmpdir} = delete $args{tmpdir} || "$rootdir/tmp";
    $self->{_logdir} = delete $args{logdir} || "$rootdir/log";
    $self->{_pkgdir} = delete $args{pkgdir} || "$rootdir/pkg";
    $self->{_image} = delete $args{image} || $image;
    $self->{_verbose} = delete $args{verbose};

    croak "bad number of arguments" if keys(%args);

    $self->{_arch} = (uname)[4];
    
    $self->clear;
    
    return $self;
}

sub rootdir  { shift->{_rootdir} };
sub spooldir { shift->{_spooldir} };
sub tmpdir   { shift->{_tmpdir} };
sub logdir   { shift->{_logdir} };
sub pkgdir   { shift->{_pkgdir} };
sub image    { shift->{_image} };
sub verbose  { shift->{_verbose} };
sub arch     { shift->{_arch} };

sub error {
    my ($self, $diag) = @_;
    push @{$self->{_error}}, $diag;
}

sub errors {
    my $self = shift;
    if (wantarray) {
	( @{$self->{_error}} );
    } else {
	@{$self->{_error}};
    }
}

sub errno {
    my $self = shift;
    croak "bad number of arguments" if @_ > 1;
    if (my $v = shift) {
	$self->{_errno} = $v;
    }
    return $self->{_errno};
}

sub is_success {
    shift->errno == E_OK;
}

sub clear {
    my $self = shift;
    $self->{_errno} = E_OK;
    $self->{_error} = [];
    delete $self->{_request};
    delete $self->{_result};
}

my %kws = (
    package => {
	mandatory => 1,
	set => \&package_name
    },
    version => {
	mandatory => 1,
	set => \&package_version
    },
    build => {
	mandatory => 0,
	set => \&package_build
    },
    slackbuild_uri => {
	mandatory => 1,
	set => \&slackbuild_uri
    },
    source_uri => {
	mandatory => 0,
	set => sub {
	    my ($self, $v) = @_;
	    $self->source_uri(new SlackBuild::URI($v));
	}
    },
    source_archive_name => {
	mandatory => 0,
	set => \&source_archive_name
    },
    prereq => {
	mandatory => 0,
	set => sub {
	    my ($self, $v) = @_;
	    if (ref($v) ne 'ARRAY') {
		$self->error("prereq: bad data type");
	    } else {
		$self->prereq($v);
	    }
	}
    },
    rc => {
	mandatory => 0,
	set => \&rc
    }
);

my @ATTRIBUTES = qw(package_name
                    package_version
                    package_build
                    rc
                    slackbuild_uri
                    source_uri);
{
    no strict 'refs';
    use feature 'state';
    foreach my $attr (@ATTRIBUTES) {
	*{ __PACKAGE__ . '::' . $attr } = sub {
	    my $self = shift;
	    croak "too many arguments" if @_ > 1;
	    if (my $v = shift) {
		$self->{_request}{$attr} = $v;
	    }
	    return $self->{_request}{$attr};
	}
    }
}

sub prereq {
    my $self = shift;
    croak "too many arguments" if @_ > 1;
    if (my $v = shift) {
	$self->{_request}{prereq} = $v;
    }
    $self->{_request}{prereq} = [] unless exists $self->{_request}{prereq};
    return $self->{_request}{prereq};
}

sub request_environ {
    my $self = shift;
    croak "too many arguments" if @_ > 1;
    if (my $v = shift) {
	$self->{_request}{environ} = $v;
    }
    $self->{_request}{environ} = {} unless exists $self->{_request}{environ};
    return $self->{_request}{environ};
}

sub environ {
    my $self = shift;
    my $env = {%{$self->request_environ},
	       VERSION => $self->package_version};
    if (my $b = $self->package_build) {
	$env->{BUILD} = $b;
    }
    return $env;
}

sub file {
    my ($self, $name) = @_;
    my $src = File::Spec->catfile($self->tmpdir, $name);
    my $dst = File::Spec->catfile($self->pkgdir, $self->osversion, $name);

    my $dstdir = dirname($dst);
    if (! -d $dstdir) {
	unless (mkdir($dstdir)) {
	    $self->error("mkdir($dstdir): $!");
	    $self->errno(E_FAIL);
	    return;
	}
    }
    
    if (-e $dst) {
	unlink $dst;
    }
    unless (move($src, $dst)) {
	$self->error("move($src, $dst): $!");
	$self->errno(E_FAIL);
    }
    push @{$self->{_result}{output_files}}, $name;
}

sub osversion {
    my $self = shift;
    croak "too many arguments" if @_ > 1;
    if (my $v = shift) {
	$self->{_osversion} = $v;
    }
    return $self->{_osversion} // "UNKNOWN";
}

sub output_files {
    my $self = shift;
    $self->{_result}{output_files} //= [];
    if (wantarray) {
	return () if $self->errno;
	return (@{$self->{_result}{output_files}});
    } else {
	return @{$self->{_result}{output_files}};
    }
}

sub wd {
    my $self = shift;
    unless ($self->{_request}{dir}) {
	$self->{_request}{dir} = tempdir(DIR => $self->spooldir, CLEANUP => 1);
    }
    return $self->{_request}{dir};
}

sub slackbuild_name {
    my $self = shift;
    return $self->package_name . '.SlackBuild';
}

sub source_archive_name {
    my $self = shift;
    croak "too many arguments" if @_ > 1;
    if (my $v = shift) {
	$self->{_request}{source_archive_name} = $v;
    }
    my $res;
    if (exists($self->{_request}{source_archive_name})) {
	$res = $self->{_request}{source_archive_name};
    } else {
	$res = basename($self->source_uri->path);
    }
    return File::Spec->catfile($self->wd, $res);
}	
    
sub run {
    my $self = shift;
    my %args;
    if (@_ == 1) {
	my $var = shift;
	%args = %{$var};
    } else {
	%args = @_;
    }

    $self->clear;
    while (my ($k,$d) = each %kws) {
	my $v = delete $args{$k};
	if (defined($v)) {
	    $self->${\ $d->{set}}($v);
	} elsif ($d->{mandatory}) {
	    $self->error("$k: not present");
	}
    }

    foreach my $k (keys %args) {
	$self->error("$k: unknown parameter");
    }
    
    if ($self->errors) {
	return $self->errno(E_SYNTAX);
    }

    my $archive = new SlackBuild::Archive($self->package_name,
					  $self->slackbuild_uri);
    
    unless ($archive->download($self->wd)) {
	$self->error("can't download $archive: "
		     . $archive->download_status);
	return $self->errno(E_FAIL);
    }

    if ($self->source_uri) {
	unless ($self->source_uri->download($self->source_archive_name)) {
	    $self->error("can't download "
			 . $self->source_archive_name
			 . ": "
			 . $self->source_uri->download_status);
	    return $self->errno(E_FAIL);
	}
    } elsif (my $d = $archive->info('DOWNLOAD')) {
	foreach my $s (split /\s+/, $d) {
	    my $uri = new SlackBuild::URI($s);
	    my $dest = File::Spec->catfile($self->wd, basename($uri->path));
	    unless ($uri->download($dest)) {
		$self->error("can't download $uri: ".$uri->download_status);
		return $self->errno(E_FAIL);
	    }
	}
    }
	
    return $self->_build;
}  

sub _runcap_diag {
    my ($self, $obj) = @_;
    if (WIFEXITED($obj->status)) {
	return if $obj->status == 0;
	while (my $s = $obj->next_line(SD_STDERR)) {
	    chomp($s);
	    $self->error($s);
	}
	$self->error("program "
		     . $obj->program
		     . " terminated with code "
		     . WEXITSTATUS($obj->status));
    } elsif (WIFSIGNALED($obj->status)) {
	$self->error("program "
		     . $obj->program
		     . " terminated on signal "
		     . WTERMSIG($obj->status));
    } else {
	$self->error("program "
		     . $obj->program
		     . " terminated with unrecogized code "
		     . $obj->status);
    }
    $self->errno(E_EXEC);
}
 
sub _logfilename {
    my $self = shift;
    return File::Spec->catfile($self->logdir, $self->package_name . '.log');
}

sub _prepare {
    my $self = shift;
    
    # Find prerequisites
    # FIXME: Build a dependency graph and spawn slackbuilders for missing ones

    # FIXME: registry type should be configurable
    my $reg = new SlackBuild::Registry('FS', dir => $self->pkgdir);

    my $filename = File::Spec->catfile($self->wd, 'rc');
    return unless SlackBuild::Rc->new($self)->write($reg, $filename);
    return 'rc';
}
    
sub _build {
    my $self = shift;
    return $self->errno if $self->errno;

    my $contname = $self->package_name . '_slackbuild';
    my $rcfile = $self->_prepare or return $self->errno(E_FAIL);
    my @args = ( 'docker',
		 'run',
		 '--rm=true',
		 '--workdir=/usr/src',
		 '-v', $self->wd . ':/usr/src',
		 '-v', $self->tmpdir . ':/tmp',
		 '-v', $self->pkgdir . ':/var/pkg:ro',
		 $self->image,
		 '/bin/sh',
		 $rcfile,
		 $self->slackbuild_name);

    print "building ".$self->package_name."\n";

    open(my $logfd, '>', $self->_logfilename)
	or do {
	    $self->error("can't create log file " .
			 $self->_logfilename .
			 ": $!");
	    return $self->errno(E_FAIL);
    };
    
    my $obj = new POSIX::Run::Capture(argv => \@args,
				      stdout => sub {
					  print $logfd 'OUT: ' . shift
				      },
				      stderr => sub {
					  my $line = shift;
					  chomp($line);
					  $self->error($line);
					  if ($self->verbose) {
					      print STDERR "$line\n";
					  }
					  print $logfd "ERR: $line\n";
				      });
    $self->{_result}{docker} = $obj;
    if ($obj->run) {
	$self->_runcap_diag($obj);
    } else {
	$self->error("can't run docker: ".strerror($obj->errno));
	return $self->errno(E_EXEC);
    }
#    $self->errno(E_FAIL) if $self->errors;

    $obj->rewind(SD_STDOUT);
    while (my $s = $obj->next_line(SD_STDOUT)) {
	chomp($s);
	if ($s =~ s{^SLACKBUILDER: VERSION }{}) {
	    $self->osversion($s);
	} elsif ($s =~ m{^Slackware package /tmp/(.+?) created}) {
	    $self->file($1);
	}
    }
    return $self->errno(E_OK);
}    


1;

Return to:

Send suggestions and report system problems to the System administrator.