aboutsummaryrefslogtreecommitdiff
path: root/gacopyz/trans.awk
blob: 6fade1acbc31ed8a2de30e14a9d5994967d84339 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
# This file is part of gacopyz.
# Copyright (C) 2006, 2007, 2009, 2010, 2011 Sergey Poznyakoff
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3, or (at your option)
# any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>. 

/#.*/ { sub("#.*","") }

NF==0 { next }

/[ \t]+/ && NF==1 {
	   if (!cur) {
	       print NR ": no current element" >"/dev/stderr"
	       next
           }
	   if (!statedecl[$1] && !undeclared[$1])
	      undeclared[$1] = NR
           trans[cur,$1] = 1
	   next
}

/^[A-Z][a-z]*/ && NF==1 {
	   states[stn++] = $1
	   statedecl[$1] = NR
	   delete undeclared[$1]	   
	   cur = $1
	   next	   
}

{ print NR ": Unrecognized line">"/dev/stderr" } 

END {
	for (st in undeclared) {
		print undeclared[st] ": " st " undeclared" >"/dev/stderr"
		count++
	}
	if (count)
		exit(1)

	print "/* -*- buffer-read-only: t -*- vi: set ro:"
        print "   THIS FILE IS GENERATED AUTOMATICALLY.  PLEASE DO NOT EDIT."
        print "*/"
		
	print "enum state {"
	print "\tst_none = -1,"		
	for (i = 0; i < stn; i++)
		print "\tst_" tolower(states[i]) ","
        print "\tst_last" 			
        print "};"
	print "char *state_name[] = {"
	for (i = 0; i < stn; i++)
		print "\t\"" tolower(states[i]) "\","
        print "};"
			
	print "char transtab[st_last][st_last] = {"
	for (i = 0; i < stn; i++) {
		printf "\t{ "
		for (j = 0; j < stn; j++)
			printf("%d, ", trans[states[i],states[j]])
		print "},"
	}	
        print "};"

	print "unsigned long state_nr_mask[] = {"
	for (i = 0; i < stn; i++) {
		if (system("grep -q SMFIP_NR_" states[i] " " header_file) == 0)
			print "\tSMFIP_NR_" states[i] ","
		else
                        print "\t0,"
	}
	print "};"
}

Return to:

Send suggestions and report system problems to the System administrator.