1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
|
# This file is part of Mailfromd. -*- autoconf -*-
# Copyright (C) 2005-2024 Sergey Poznyakoff
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3, or (at your option)
# any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
AC_PREREQ([2.71])
m4_define([MF_VERSION_MAJOR], 9)
m4_define([MF_VERSION_MINOR], 0)
dnl m4_define([MF_VERSION_PATCH], 0)
AC_INIT([mailfromd],
MF_VERSION_MAJOR.MF_VERSION_MINOR[]m4_ifdef([MF_VERSION_PATCH],.MF_VERSION_PATCH),
[bug-mailfromd@gnu.org.ua],
[mailfromd],
[http://www.gnu.org.ua/software/mailfromd])
AC_CONFIG_SRCDIR([src/mailfromd.h])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([1.16.5 gnits tar-ustar dist-bzip2 dist-xz std-options silent-rules])
# Enable silent rules by default:
AM_SILENT_RULES([yes])
#
AC_DEFINE_UNQUOTED([MAILFROMD_VERSION_MAJOR], MF_VERSION_MAJOR,
[Major version number])
AC_DEFINE_UNQUOTED([MAILFROMD_VERSION_MINOR], MF_VERSION_MINOR,
[Minor version number])
AC_DEFINE_UNQUOTED([MAILFROMD_VERSION_PATCH],
m4_ifdef([MF_VERSION_PATCH],MF_VERSION_PATCH,0),
[Patchlevel number])
# Checks for programs.
AC_PROG_CC
AC_PROG_LN_S
PKG_PROG_PKG_CONFIG
AC_PATH_PROG([BISON],[bison],[\$(SHELL) \$(top_srcdir)/build-aux/missing bison])
AC_PATH_PROG([FLEX],[flex],[\$(SHELL) \$(top_srcdir)/build-aux/missing flex])
LT_INIT
# Debugging mode
MU_DEBUG_MODE
MF_GCC_QUIRKS
# Checks for libraries.
AC_CHECK_LIB(socket, socket)
AC_CHECK_LIB(nsl, gethostbyaddr)
AC_CHECK_LIB(rt, nanosleep)
# Checks for header files.
AC_CHECK_HEADERS([sysexits.h paths.h])
# Checks for typedefs, structures, and compiler characteristics.
IU_CHECK_MEMBERS([struct msghdr.msg_control, struct msghdr.msg_accrights], , ,
[#include <sys/types.h>
#include <sys/socket.h>])
# Checks for library functions.
AC_CHECK_FUNCS([setegid setregid setresgid seteuid setreuid \
sysconf getdtablesize])
AC_REPLACE_FUNCS(daemon)
# Check for GNU Mailutils
AM_GNU_MAILUTILS([3.4], [all auth dbm sieve], [:])
if test "$($MAILUTILS_BIN info WITH_GNUTLS)" = "WITH_GNUTLS"; then
status_gnutls=1
else
status_gnutls=0
fi
AC_DEFINE_UNQUOTED([WITH_MAILUTILS_GNUTLS], [$status_gnutls], [Whether mailutils supports GnuTLS])
AC_CHECK_LIB([adns], [adns_init],,
[AC_MSG_ERROR([required library libadns not found])])
AC_SUBST([NETTLE_LIBS])
AC_CHECK_HEADERS([nettle/sha2.h nettle/buffer.h nettle/rsa.h nettle/base64.h])
if test "$ac_cv_header_nettle_sha2_h$ac_cv_header_nettle_buffer_h$ac_cv_header_nettle_rsa_h$ac_cv_header_nettle_base64_h" = "yesyesyesyes"; then
AC_CHECK_LIB([gmp],[__gmpz_init],
[AC_CHECK_LIB([hogweed],[nettle_rsa_sha256_sign],[
AC_CHECK_LIB([nettle],[nettle_sha256_init],[
NETTLE_LIBS="-lhogweed -lnettle -lgmp"
],[],[-lgmp])])])
fi
AM_CONDITIONAL([NETTLE_COND],[test -n "$NETTLE_LIBS"])
if test -n "$NETTLE_LIBS"; then
AC_DEFINE([WITH_DKIM], [1], [Enable DKIM functions])
fi
### Check for Emacs site-lisp directory
AM_PATH_LISPDIR
if test "$EMACS" != "no"; then
lisp_LISP='$(LISPSRC)'
fi
AC_SUBST(lisp_LISP)
# Gettext.
AM_GNU_GETTEXT([external], [need-formatstring-macros])
AM_GNU_GETTEXT_VERSION([0.19])
# Syslog
AC_ARG_ENABLE([syslog-async],
AS_HELP_STRING([--enable-syslog-async],
[compile non-blocking version of syslog]),
[case "${enableval}" in
yes) syslog_async=yes ;;
no) syslog_async=no ;;
*) AC_MSG_ERROR([bad value ${enableval} for --enable-syslog-async]) ;;
esac],[syslog_async=no])
if test $syslog_async = "yes"; then
AC_ARG_VAR([DEFAULT_SYSLOG_ASYNC],
[Define to 1 if syslog-async is being used by default])
if test -z "$DEFAULT_SYSLOG_ASYNC"; then
DEFAULT_SYSLOG_ASYNC=0
fi
AC_DEFINE_UNQUOTED([DEFAULT_SYSLOG_ASYNC],$DEFAULT_SYSLOG_ASYNC,
[Define to 1 to use syslog_async by default])
AC_SUBST([BUILD_SYSLOG_ASYNC], '$(SYSLOG_ASYNC_O)')
AC_DEFINE([USE_SYSLOG_ASYNC], [1], [Define if syslog-async is being used])
fi
# ######################
# Default database type
# ######################
# A map of supported database types. The format is DBTYPE:FEATURE,
# where FEATURE is the corresponding mailutils feature as listed by
# 'mailutils info', without the WITH_ prefix and converted to lowercase.
# The entries are sorted in ascending preference order.
# Traditionally Mailfromd preferred Berkeley DB over GDBM.
db_map="
bdb:bdb
gdbm:gdbm
kc:kyotocabinet
tc:tokyocabinet
ndbm:ndbm
"
# Convert database type to mailutils feature
db_type_to_feature() {
# Normalize the input
key=$(echo "$1" | tr A-Z a-z)
# Augment db_map with the line "$key:$key" and select from the resulting
# input the first entry starting with "$key:". On output, replace it with
# the characters that follow : up to the newline.
# The first expression looks for the string in the first line of input.
# If found, it replaces it and branches to the end of script. The second
# expression then has no chance to catch, since the scanning resumes from
# line 2. Otherwise, if key is not found in the first line, the second
# expression searches for it in the remaining lines.
# The default entry "$key:$key" ensures the normalized key is returned
# if no match was found.
sed -n -e "1s/^$key"'://p;t' -e '1,//{s///p}' <<EOF
$db_map
$key:$key
EOF
}
# Convert mailutils feature to the database type
db_feature_to_type() {
sed -n /:$(echo "$1" | tr A-Z a-z)'$/s/:.*//p' <<EOF
$db_map
EOF
}
# Produce the list of mailutils DBM features
db_feature_list() {
sed 's/^.*://' <<EOF
$db_map
EOF
}
AC_ARG_VAR([DEFAULT_DB_TYPE],[Set default database type])
AC_ARG_WITH([gdbm],
AS_HELP_STRING([--with-gdbm],
[use GNU DBM by default]),
[
case "${withval}" in
yes) DEFAULT_DB_TYPE=gdbm;;
no) ;;
*) AC_MSG_ERROR(bad value ${withval} for --with-gdbm) ;;
esac])
AC_ARG_WITH([berkeley-db],
AS_HELP_STRING([--with-berkeley-db],
[use Berkeley DB by default]),
[
case "${withval}" in
no) ;;
*) DEFAULT_DB_TYPE=bdb;;
esac])
AC_ARG_WITH([dbm],
AS_HELP_STRING([--with-dbm=TYPE],
[set default DBM type]),
[DEFAULT_DB_TYPE=$withval])
AH_TEMPLATE([DEFAULT_DB_TYPE], [Define default database type])
if test -n "$DEFAULT_DB_TYPE"; then
if ! mailutils info $(db_type_to_feature $DEFAULT_DB_TYPE) >/dev/null; then
AC_MSG_ERROR([requested DBM type $DEFAULT_DB_TYPE not supported by Mailutils])
fi
else
fl=$(db_feature_list)
feature=$(mailutils info $fl | head -n 1 | sed 's/WITH_//')
if test -n "$feature"; then
DEFAULT_DB_TYPE=$(db_feature_to_type $feature)
if test -z "$DEFAULT_DB_TYPE"; then
AC_MSG_WARN([can't select database type $feature, falling back to default])
fi
fi
fi
if test -n "$DEFAULT_DB_TYPE"; then
AC_DEFINE_UNQUOTED([DEFAULT_DB_TYPE], "$DEFAULT_DB_TYPE")
status_dbm=$DEFAULT_DB_TYPE
else
AC_DEFINE_UNQUOTED([DEFAULT_DB_TYPE], NULL)
fi
## Preprocessor
AC_ARG_WITH([preprocessor],
AS_HELP_STRING([--without-preprocessor],
[do not use external preprocessor]),
[
case "${withval}" in
yes) use_ext_pp=yes ;;
no) use_ext_pp=no ;;
*) AC_MSG_ERROR(bad value ${withval} for --with-preprocessor) ;;
esac],[use_ext_pp=yes])
AC_ARG_VAR([DEFAULT_PREPROCESSOR],
[Set default preprocessor name])
if test -z "$DEFAULT_PREPROCESSOR" ; then
DEFAULT_PREPROCESSOR="m4 -s"
fi
if test $use_ext_pp != no; then
save_PATH=$PATH
PREPROC_OPTIONS=`echo $DEFAULT_PREPROCESSOR | sed -n 's/[[^ ]][[^ ]]* //p'`
case "$DEFAULT_PREPROCESSOR" in
/*) PATH=`expr "$DEFAULT_PREPROCESSOR" : '\(.*\)/.*'`:$PATH
DEFAULT_PREPROCESSOR=`expr "$DEFAULT_PREPROCESSOR" : '.*/\(.*\)'`;;
esac
AC_PATH_PROG(PPBIN, $DEFAULT_PREPROCESSOR)
DEFAULT_PREPROCESSOR=$PPBIN
if test -n "$DEFAULT_PREPROCESSOR"; then
use_ext_pp=yes
DEFAULT_PREPROCESSOR="$DEFAULT_PREPROCESSOR $PREPROC_OPTIONS"
case $PPBIN in
*m4) AC_SUBST(PP_SETUP_FILE,'pp-setup');; # Install default pp-setup
esac
else
use_ext_pp=no
fi
PATH=$save_PATH
else
unset DEFAULT_PREPROCESSOR
fi
AM_CONDITIONAL([PREPROC_COND], [test "$use_ext_pp" = yes])
AC_ARG_WITH([readline],
AS_HELP_STRING([--without-readline],
[do not use readline]),
[
case "${withval}" in
yes) usereadline=yes ;;
no) usereadline=no ;;
*) AC_MSG_ERROR(bad value ${withval} for --without-readline) ;;
esac],[usereadline=maybe])
# Test for GNU Readline
AC_SUBST(READLINE_LIBS)
if test "$usereadline" != "no"; then
dnl FIXME This should only link in the curses libraries if it's
dnl really needed!
dnl Check for Curses libs.
CURSES_LIBS=
for lib in ncurses curses termcap
do
AC_CHECK_LIB($lib, tputs, [CURSES_LIBS="-l$lib"; break])
done
saved_LIBS=$LIBS
LIBS="$LIBS $CURSES_LIBS"
AC_CHECK_LIB(readline, readline, mf_have_readline=yes)
LIBS=$saved_LIBS
if test "$mf_have_readline" = "yes"; then
AC_CHECK_HEADERS(readline/readline.h,
AC_DEFINE(WITH_READLINE,1,[Enable use of readline]))
READLINE_LIBS="-lreadline $CURSES_LIBS"
saved_LIBS=$LIBS
LIBS="$LIBS $READLINE_LIBS"
AC_CHECK_FUNCS(rl_completion_matches)
LIBS=$saved_LIBS
usereadline="yes"
else
if test "$usereadline" = "yes"; then
AC_MSG_WARN(readline requested but does not seem to be installed)
fi
usereadline="no"
fi
fi
AH_BOTTOM([
/* Some older versions of readline have completion_matches */
#ifndef HAVE_RL_COMPLETION_MATCHES
# define rl_completion_matches completion_matches
#endif])
AC_SUBST(MILTER, '../gacopyz/libgacopyz.a')
AC_SUBST(MILTER_INCLUDES, '-I$(top_srcdir)/gacopyz')
# Set default state directory
AC_SUBST(DEFAULT_STATE_DIR)
AC_MSG_CHECKING(for default mfd state directory)
AC_ARG_VAR([DEFAULT_STATE_DIR],
[Set default mfd state directory])
if test -z "$DEFAULT_STATE_DIR"; then
DEFAULT_STATE_DIR='$(localstatedir)/$(PACKAGE)'
fi
AC_MSG_RESULT($DEFAULT_STATE_DIR)
# Prepare default socket spec
AC_SUBST(DEFAULT_SOCKET)
AC_MSG_CHECKING(for default communication socket)
AC_ARG_VAR([DEFAULT_SOCKET],
[Set default communication socket.])
if test -z "$DEFAULT_SOCKET"; then
DEFAULT_SOCKET='mailfrom'
fi
AC_MSG_RESULT($DEFAULT_SOCKET)
# Test for default user name
AC_SUBST(DEFAULT_USER)
AC_MSG_CHECKING(for default user name)
AC_ARG_VAR([DEFAULT_USER],
[Set default user name])
if test -z "$DEFAULT_USER"; then
DEFAULT_USER=mail
fi
AC_MSG_RESULT($DEFAULT_USER)
AC_DEFINE_UNQUOTED(DEFAULT_USER, "$DEFAULT_USER", [Default mfd user])
# Test for default expiration interval
AC_SUBST(DEFAULT_EXPIRE_INTERVAL)
AC_MSG_CHECKING(for default expiration interval)
AC_ARG_VAR([DEFAULT_EXPIRE_INTERVAL],
[Set default expiration interval])
if test -z "$DEFAULT_EXPIRE_INTERVAL"; then
DEFAULT_EXPIRE_INTERVAL=86400
fi
AC_MSG_RESULT($DEFAULT_EXPIRE_INTERVAL)
AC_DEFINE_UNQUOTED(DEFAULT_EXPIRE_INTERVAL, $DEFAULT_EXPIRE_INTERVAL,
[Default expiration interval])
# Test for default log facility
AC_SUBST(DEFAULT_LOG_FACILITY)
AC_MSG_CHECKING(for default log facility)
AC_ARG_VAR([DEFAULT_LOG_FACILITY],
[Set default log facility])
if test -z "$DEFAULT_LOG_FACILITY"; then
DEFAULT_LOG_FACILITY=mail
fi
DEFAULT_LOG_FACILITY=`echo $DEFAULT_LOG_FACILITY | tr a-z A-Z`
case $DEFAULT_LOG_FACILITY in
LOG_*) ;;
*) DEFAULT_LOG_FACILITY=LOG_$DEFAULT_LOG_FACILITY;;
esac
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <syslog.h>]],
[[int lf = $DEFAULT_LOG_FACILITY]])],
[:],
[AC_MSG_ERROR($DEFAULT_LOG_FACILITY: Unknown syslog facility)])
AC_MSG_RESULT($DEFAULT_LOG_FACILITY)
AC_DEFINE_UNQUOTED(DEFAULT_LOG_FACILITY, $DEFAULT_LOG_FACILITY,
[Default log facility])
# Test for setproctitle
MF_PROCTITLE
# Test for libpmilter
AC_SUBST(META1_LIBS)
AC_SUBST(META1_INCLUDES)
AC_ARG_ENABLE([pmilter],
AS_HELP_STRING([--enable-pmilter[[=PATH]]],
[enable pmilter support]),
[case "${enableval}" in
yes) enable_pmilter=yes;;
no) enable_pmilter=no;;
/*) dir=$enableval/lib/mta
if test -d $dir; then
META1_LIBS="-L$dir"
else
AC_MSG_ERROR([$dir: No such directory])
fi
dir=$enableval/include
if test -d $dir/sm; then
META1_INCLUDES="-I$dir"
else
AC_MSG_ERROR([$dir: No such directory])
fi
enable_pmilter=yes
;;
*) AC_MSG_ERROR([Bad argument to --enable-pmilter])
esac],[enable_pmilter=no])
if test "$enable_pmilter" = yes; then
saved_LIBS=$LIBS
AC_SUBST(PTHREAD_LIBRARIES)
AC_CHECK_LIB(pthread, pthread_self,
[ have_pthread=yes
PTHREAD_LIBRARIES="-lpthread -lc" ],
[ PTHREAD_LIBRARIES="-lpthread"
AC_CHECK_FUNC(pthread_self,
[HAVE_PTHREAD=yes]) ])
if test $have_pthread != yes; then
AC_MSG_ERROR([POSIX threads library not found. Please install it and then reconfigure])
fi
save_CPPFLAGS=$CPPFLAGS
CPPFLAGS="$CPPFLAGS $META1_INCLUDES"
AC_CHECK_HEADERS([sm/error.h sm/hdrmoddef.h sm/pmfapi.h sm/pmilter.h sm/smreplycodes.h sm/generic.h sm/mfapi.h sm/pmfdef.h sm/smmts.h],
[],
[AC_MSG_ERROR([Required header file $ac_header not found])],
[
#ifdef HAVE_SM_ERROR_H
# include <sm/error.h>
#endif])
CFFPLAGS=$save_CPPFLAGS
libs="pmilter pmutil evthr thr rcbcommr rcbr mtar cstrr replr"
save_LDFLAGS=$LDFLAGS
LDFLAGS="$LDFLAGS $META1_LIBS"
for file in $libs
do
AC_CHECK_LIB($file, main,
[META1_LIBS="$META1_LIBS -l$file"],
[AC_MSG_ERROR([Required library lib$file not found])])
done
LDFLAGS=$save_LDFLAGS
IU_CHECK_MEMBERS([struct pmilter_S.pmfi_thrmax_s,
struct pmilter_S.pmfi_thrmax_h,
struct pmilter_S.pmfi_fdmax], , ,
[#include "sm/error.h"
#include "sm/smreplycodes.h"
#include "sm/pmilter.h"
#include "sm/pmfdef.h"
#include "sm/pmfapi.h"])
LIBS="$LIBS $META1_LIBS"
AC_CHECK_FUNCS([sm_pmfi_setmacs])
LIBS=$saved_LIBS
fi
AM_CONDITIONAL([PMULT_COND], [test "$enable_pmilter" = yes])
# GeoIP2
AC_ARG_WITH([geoip2],
AS_HELP_STRING([--with-geoip2],
[use MaxMind GeoIP2 library]),
[
case "${withval}" in
yes) status_geoip2=yes ;;
no) status_geoip2=no ;;
*) AC_MSG_ERROR(bad value ${withval} for --with-geoip2) ;;
esac],[status_geoip2=maybe])
if test "$status_geoip2" != "no"; then
PKG_CHECK_MODULES([GEOIP2], [libmaxminddb], [status_geoip2=yes], [
if test $status_geoip2 = "yes"; then
AC_MSG_WARN(libmaxminddb requested but does not seem to be installed)
fi
status_geoip2="no"])
fi
if test "$status_geoip2" = "yes"; then
AC_DEFINE([WITH_GEOIP2], [1], [Enable use of Maxmind GeoIP2 library])
fi
## Support for dynamically loaded modules
AC_ARG_ENABLE([mfmod],
AS_HELP_STRING([--enable-mfmod],
[enable support for dynamically loaded modules]),
[case $enableval in
yes|no) status_mfmod=$enableval;;
*) AC_MSG_ERROR([bad value ${enableval} for --enable-mfmod]);;
esac],
[status_mfmod=probe])
AC_SUBST([DLFCN_LIBS])
if test $status_mfmod != no; then
AC_CHECK_HEADERS([dlfcn.h],
[AC_CHECK_FUNC(dlopen,
[status_mfmod=yes],
[AC_CHECK_LIB(dl, dlopen,
[status_mfmod=yes
DLFCN_LIBS=-ldl],
[status_mfmod=no])])],
[status_mfmod=no])
fi
AM_CONDITIONAL([MFMOD_COND],[test $status_mfmod = yes])
if test $status_mfmod = yes; then
AC_DEFINE([WITH_MFMOD], [1], [Enable support for dynamically loaded modules])
fi
## Imprimatur
IMPRIMATUR_INIT
if test $RENDITION = "PROOF"; then
if test -r $srcdir/git-describe; then
GIT_DESCRIBE=`sed '2,$d' $srcdir/git-describe`
AC_DEFINE_UNQUOTED([GIT_DESCRIBE], "$GIT_DESCRIBE",
[The most recent git tag])
fi
fi
# Initialize the test suite.
AC_CONFIG_TESTDIR(tests)
AC_CONFIG_FILES([tests/Makefile tests/atlocal])
AM_MISSING_PROG([AUTOM4TE], [autom4te])
AC_CONFIG_COMMANDS([status],[
cat <<EOF
*******************************************************************
Mailfromd configured with the following settings:
Mailutils version......................... $mu_version
External preprocessor..................... $ext_pp
DBM version............................... $status_dbm
Default user.............................. $user
State directory........................... $stat_dir
Socket.................................... $socket
Expiration interval....................... $expire
Compile asynchronous syslog............... $syslog_async
Readline (for mtasim)..................... $usereadline
Documentation rendition type.............. $rendition
Enable pmilter support.................... $enable_pmilter
Enable GeoIP2 support..................... $status_geoip2
Enable DKIM support....................... $status_dkim
Dynamically loaded modules (mfmod)........ $status_mfmod
Callout STARTTLS.......................... $status_callout_starttls
*******************************************************************
EOF
],
[mu_version=$MAILUTILS_VERSION
if test -z "$DEFAULT_PREPROCESSOR"; then
ext_pp=no
else
ext_pp="$DEFAULT_PREPROCESSOR"
fi
status_dbm="$status_dbm"
stat_dir='$DEFAULT_STATE_DIR'
socket='$DEFAULT_SOCKET'
user=$DEFAULT_USER
expire=$DEFAULT_EXPIRE_INTERVAL
usereadline=$usereadline
rendition=$RENDITION
syslog_async=$syslog_async
enable_pmilter=$enable_pmilter
status_geoip2=$status_geoip2
if test -n "$NETTLE_LIBS"; then
status_dkim=yes
else
status_dkim=no
fi
status_mfmod=$status_mfmod
if test "$status_gnutls" = 1; then
status_callout_starttls=yes
else
status_callout_starttls=no
fi
])
AC_CONFIG_FILES([Makefile
lib/Makefile
gacopyz/Makefile
src/Makefile
src/builtin/Makefile
mflib/Makefile
mfmod/Makefile
mtasim/Makefile
pmult/Makefile
elisp/Makefile
po/Makefile.in
etc/Makefile
doc/Makefile])
AC_OUTPUT
|