divert(-1)
# This file is part of mailfromd.
# Copyright (C) 2006, 2007 Sergey Poznyakoff
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3, or (at your option)
# any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

changequote([<,>])
changecom(/*,*/)

define([<__makedebugtab>],[<dnl
ifelse($2,,,
[<ifelse(regexp($2,[<\(.*\)\.[cyl]>],[<\1>]),,
[<__makedebugtab($1,shift(shift($@)))>],
[<	"patsubst($2,\(.*\)\.[cyl],\1)", 
>]dnl
[<__makedebugtab(incr($1),shift(shift($@)))>])>])>])

define([<MAKEDEBUGTAB>],[<__makedebugtab(1, $*)>])

define([<__makedebugsym>],[<dnl
ifelse($2,,,
[<ifelse(regexp($2,[<\(.*\)\.[cyl]>],[<\1>]),,
[<__makedebugsym($1,shift(shift($@)))>],
[<#define [<MF_SOURCE_>]translit(patsubst($2,\(.*\)\.[cyl],\1), [<a-z->],dnl
[<A-Z_>]) $1
>]dnl
[<__makedebugsym(incr($1),shift(shift($@)))>])>])>])

define([<MAKEDEBUGSYM>],[<__makedebugsym(1, $*)>])

define([<__arglist>],[<dnl
ifelse($1,$2,x$1,
[<x$1, __arglist(incr($1), $2)>])>])

define([<MKDEBUG>],[<
[<#define __debug>]$1[<(fmt, >]__arglist(1,$1))  \[<
 do {                                                                         \
   if (source_info_option)                                                    \
    debug_log("%s:%lu:%s: " fmt, __FILE__, __LINE__, __FUNCTION__, >]dnl
__arglist(1,$1)[<); \
   else                                                                       \
    debug_log(fmt,>]dnl
__arglist(1,$1)[<);\
 } while (0)                                                                  
#define debug>]$1[<(lev, fmt, >]__arglist(1,$1)[<) \
 do { __DBG(lev) __debug>]$1[<(fmt, >]__arglist(1,$1)[<); } while(0)
>]>])

divert(0)dnl
/* -*- buffer-read-only: t -*- vi: set ro:
   THIS FILE IS GENERATED AUTOMATICALLY.  PLEASE DO NOT EDIT.
*/