aboutsummaryrefslogtreecommitdiff
path: root/src/bind-gram.y
blob: 621070ebf4cc81adf59ec63be8836ab768e6c4cd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
%{
/* grecs - Gray's Extensible Configuration System
   Copyright (C) 2007-2011 Sergey Poznyakoff

   Grecs is free software; you can redistribute it and/or modify it
   under the terms of the GNU General Public License as published by the
   Free Software Foundation; either version 3 of the License, or (at your
   option) any later version.

   Grecs is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License along
   with Grecs. If not, see <http://www.gnu.org/licenses/>. */

#ifdef HAVE_CONFIG_H
# include <config.h>
#endif
#include <grecs.h>
#include <grecs-gram.h>
#include <stdlib.h>
#include <stdarg.h>
#include <string.h>
#include <errno.h>

int yylex(void);
int yyerror(char *s);

static struct grecs_node *parse_tree;
extern int yy_flex_debug;
extern int grecs_bind_new_source(const char *name);
extern void grecs_bind_close_sources(void);

static struct grecs_value *stmtlist_to_value(struct grecs_node *node);
%}

%union {
	struct {
		grecs_locus_t locus;
		char *string;
	} ident;
	char *string;
	grecs_value_t svalue, *pvalue;
	struct grecs_list *list;
	struct grecs_node *node;
	grecs_locus_t locus;
	struct { struct grecs_node *head, *tail; } node_list;
}

%token <ident> BIND_IDENT
%token <string> BIND_STRING
%type <string> string
%type <svalue> value
%type <pvalue> vallist tag
%type <list> vlist
%type <node> stmt simple block
%type <node_list> stmtlist

%%

input   : stmtlist
          {
		  parse_tree = grecs_node_create(grecs_node_root,
						 &grecs_current_locus);
		  parse_tree->v.texttab = grecs_text_table();
		  grecs_node_bind(parse_tree, $1.head, 1);
	  }
        ;

stmtlist: stmt
          {
		  $$.head = $$.tail = $1;
	  } 
        | stmtlist stmt
	  {
		  if ($2) {
			  if (!$1.head)
				  $1.head = $1.tail = $2;
			  else
				  grecs_node_bind($1.tail, $2, 0);
		  }
		  $$ = $1;
	  }
        ;

stmt    : simple
        | block
        ;

simple  : BIND_IDENT vallist ';'
          {
		  if (strcmp($1.string, "include") == 0 &&
		      $2->type == GRECS_TYPE_STRING) {
			  grecs_bind_new_source($2->v.string);
			  $$ = NULL;
		  } else {
			  $$ = grecs_node_create(grecs_node_stmt, &$1.locus);
			  $$->ident = $1.string;
			  $$->v.value = $2;
		  }
	  }
        | string ';'
	  {
		  $$ = grecs_node_create(grecs_node_stmt,
					 &grecs_current_locus);
		  $$->ident = $1;
		  $$->v.value = NULL;
	  }
        ;

block   : BIND_IDENT tag '{' stmtlist '}' opt_sc
          {
		  $$ = grecs_node_create(grecs_node_block, &$1.locus);
		  $$->ident = $1.string;
		  $$->v.value = $2;
		  grecs_node_bind($$, $4.head, 1);
	  }
        ;

tag     : /* empty */
          {
		  $$ = NULL;
	  }
        | BIND_IDENT
	  {
		  $$ = grecs_malloc(sizeof($$[0]));
		  $$->type = GRECS_TYPE_STRING;
		  $$->v.string = $1.string;
	  }		  
        | BIND_STRING
	  {
		  $$ = grecs_malloc(sizeof($$[0]));
		  $$->type = GRECS_TYPE_STRING;
		  $$->v.string = $1;
	  }		  
        ;

vallist : vlist
          {
		  size_t n;
		  
		  if ((n = grecs_list_size($1)) == 1) {
			  $$ = grecs_list_index($1, 0);
		  } else {
			  size_t i;
			  struct grecs_list_entry *ep;
		
			  $$ = grecs_malloc(sizeof($$[0]));
			  $$->type = GRECS_TYPE_ARRAY;
			  $$->v.arg.c = n;
			  $$->v.arg.v = grecs_calloc(n,
						     sizeof($$->v.arg.v[0]));
			  for (i = 0, ep = $1->head; ep; i++, ep = ep->next)
				  $$->v.arg.v[i] = ep->data;
		  }
		  $1->free_entry = NULL;
		  grecs_list_free($1);	      
	  }
	;

vlist   : value
          {
		  $$ = grecs_value_list_create();
		  grecs_list_append($$, grecs_value_ptr_from_static(&$1));
	  }
        | vlist value
          {
		  grecs_list_append($1, grecs_value_ptr_from_static(&$2));
	  }
        | vlist BIND_IDENT '{' stmtlist '}'
	  /* This production handles constructs that don't fit well into
	     hierarchical structure, namely, the "controls" statement, e.g.:

	     controls {
                 inet 127.0.0.1 port 953
                     allow { 127.0.0.1; 127.0.0.2; } keys { "rndc-key"; };
             };

	     This statement produces:
	     
	     .controls.inet: 127.0.0.1 port 953 allow (127.0.0.1) keys
	                     (rndc-key)
	  */
	  {
		  struct grecs_value *val = grecs_malloc(sizeof(*val));
		  val->type = GRECS_TYPE_STRING;
		  val->v.string = $2.string;
		  grecs_list_append($1, val);
		  
		  val = stmtlist_to_value($4.head);
		  /* FIXME: Free $4 */
		  grecs_list_append($1, val);
	  }
        ;

value   : string
          {
		  $$.type = GRECS_TYPE_STRING;
		  $$.v.string = $1;
	  }
        ;        

string  : BIND_STRING
        | BIND_IDENT
          {
		  $$ = $1.string;
	  }
        ;

opt_sc  : /* empty */
        | ';'
        ;

%%

int
yyerror(char *s)
{
	grecs_error(&grecs_current_locus, 0, "%s", s);
	return 0;
}

struct grecs_node *
grecs_bind_parser(const char *name, int traceflags)
{
	int rc;

	if (grecs_bind_new_source(name))
		return NULL;
	yy_flex_debug = traceflags & GRECS_TRACE_LEX;
	yydebug = traceflags & GRECS_TRACE_GRAM;
	parse_tree = NULL;
	grecs_line_acc_create();
	rc = yyparse();
	grecs_bind_close_sources();
	if (grecs_error_count)
		rc = 1;
	grecs_line_acc_free();
	if (rc) {
		grecs_tree_free(parse_tree);
		parse_tree = NULL;
	}
	return parse_tree;
}

static struct grecs_value *
node_to_value(struct grecs_node *node, struct grecs_txtacc *acc)
{
	struct grecs_value *val = grecs_malloc(sizeof(*val));
	int delim = 0;
	
	if (node->ident) {
		grecs_txtacc_grow(acc, node->ident, strlen(node->ident));
		delim = 1;
	}
	
	if (node->v.value) {
		if (delim)
			grecs_txtacc_grow_char(acc, ' ');
		grecs_txtacc_format_value(node->v.value, 0, acc);
		delim = 1;
	}
	if (node->type == grecs_node_stmt) {
		val->type = GRECS_TYPE_STRING;
		grecs_txtacc_grow_char(acc, 0);
		val->v.string = grecs_txtacc_finish(acc, 1);
	} else if (node->down) {
		struct grecs_list *list = grecs_value_list_create();
		struct grecs_node *np;

		if (delim)
			grecs_txtacc_grow_char(acc, ' ');
		for (np = node->down; np; np = np->next)
			grecs_list_append(list, node_to_value(np, acc));
		val->type = GRECS_TYPE_LIST;
		val->v.list = list;
	}
	return val;
}

static struct grecs_value *
stmtlist_to_value(struct grecs_node *node)
{
	struct grecs_txtacc *acc = grecs_txtacc_create();
	struct grecs_value *val;
	struct grecs_node parent;

	memset(&parent, 0, sizeof(parent));
	parent.type = grecs_node_block;
	parent.down = node;
	val = node_to_value(&parent, acc);
	grecs_txtacc_free(acc);
	return val;
}

Return to:

Send suggestions and report system problems to the System administrator.