dnl This file is part of Gamma
dnl Copyright (C) 2002, 2004, 2007 Sergey Poznyakoff
dnl
dnl This program is free software; you can redistribute it and/or modify it
dnl under the terms of the GNU General Public License as published by the
dnl Free Software Foundation; either version 3 of the License, or (at your
dnl option) any later version.
dnl
dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License along
dnl with this program. If not, see <http://www.gnu.org/licenses/>. */

dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)

AC_INIT(gamma, 1.1, [gray@gnu.org.ua])
AC_CONFIG_SRCDIR(src/guile-sql.h)
AC_CONFIG_AUX_DIR([scripts])
AC_CANONICAL_SYSTEM
AM_INIT_AUTOMAKE
AC_CONFIG_HEADERS([config.h])

dnl Checks for programs.
AC_PROG_AWK
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AM_PROG_LIBTOOL
AM_C_PROTOTYPES

AC_SUBST(INCLUDEPATH)
AC_MSG_CHECKING(for additional includes)
AC_ARG_WITH(include-path,
	[  --with-include-path=PATH      specify additional include paths.
                                         PATH is a ':' separated list of additional
                                         include paths.  ],
	[ for path in `echo $withval | sed 's/:/ /g'`
          do
            INCLUDEPATH="$INCLUDEPATH -I$path"
          done])
AC_MSG_RESULT($INCLUDEPATH)

AC_MSG_CHECKING(for additional libraries)
AC_ARG_WITH(lib-path,    
	[  --with-lib-path=PATH          specify additional library paths.],
	[ for path in `echo $withval | sed 's/:/ /g'`
          do
            LIBS="$LIBS -L$path"
          done])
AC_MSG_RESULT($LIBS)

dnl Checks for libraries.
MU_CHECK_GUILE

dnl Checks for gettext
AC_CHECK_HEADERS(locale.h)
AM_GNU_GETTEXT(external, need-ngettext)
AM_GNU_GETTEXT_VERSION(0.13)

dnl Checks for library functions.
AC_HEADER_STDC
AC_CHECK_FUNCS(strdup)

if test $mu_cv_lib_guile = yes; then
  MYSQL=yes
  PGSQL=yes

  AC_ARG_WITH(mysql,
          [  --without-mysql        Configure to work without MySQL],
	  [MYSQL=$withval])
  AC_ARG_WITH(postgres,
          [  --without-postgres     Configure to work without Postgres],
	  [PGSQL=$withval])

  SQLLIBS=""
  # Check individual libraries
  RA_CHECK_LIB(mysqlclient, mysql_real_connect, "-lm",
              [ AC_DEFINE(USE_SQL_MYSQL,1,
                          [Define this if you are going to use MySQL])
                AC_DEFINE(HAVE_LIBMYSQL,1,
                          [Define this if you have mysqlclient library])
                SQLLIBS="$SQLLIBS $ra_cv_lib_mysqlclient" ],
              [ MYSQL=no ],
              [/usr/local/lib/mysql /usr/lib/mysql])

  RA_CHECK_LIB(pq, PQconnectStart, [],
  	      [ AC_DEFINE(USE_SQL_PGSQL,1,
                          [Define this if you are going to use PostgreSQL])
                AC_DEFINE(HAVE_LIBPQ,1,
                          [Define this if you have libp]) 
                SQLLIBS="$SQLLIBS $ra_cv_lib_pq" ],
              [ PGSQL=no ],
              [/usr/local/pgsql/lib /usr/pgsql/lib])

  if test "x$SQLLIBS" != "x"; then
    LIBS="$LIBS $SQLLIBS"
    BUILD_LIBS="$BUILD_LIBS \$(LIB_SQL)"
    BUILD_DATA="$BUILD_DATA \$(SCM_SQL)"
    BUILD_X="$BUILD_X \$(X_SQL)"
    INSTALL_HOOKS="$INSTALL_HOOKS install-sql-hook"

    if test $MYSQL = yes ; then
      AC_LIBOBJ(mysql)
    fi
    if test $PGSQL = yes ; then
      AC_LIBOBJ(pgsql)
    fi
  fi
fi

if test x"$USE_NLS" != x; then
  BUILD_DATA="$BUILD_DATA \$(SCM_GETTEXT)"
fi

if test x"$BUILD_LIBS" = x; then
  AC_MSG_ERROR([Nothing to build!])
fi

AC_SUBST(BUILD_LIBS)
AC_SUBST(BUILD_DATA)
AC_SUBST(BUILD_X)
AC_SUBST(INSTALL_HOOKS)

AC_CONFIG_FILES(Makefile src/Makefile scripts/Makefile examples/Makefile po/Makefile.in)

AC_OUTPUT