summaryrefslogtreecommitdiffabout
path: root/lib/forlangrm.y
blob: 1b7781d3ab7c952f5db3ada2ebd6dc0e77889183 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
%{
/* This file is part of Eclat.
   Copyright (C) 2012 Sergey Poznyakoff.
 
   Eclat is free software; you can redistribute it and/or modify
   it under the terms of the GNU General Public License as published by
   the Free Software Foundation; either version 3, or (at your option)
   any later version.
 
   Eclat is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.
 
   You should have received a copy of the GNU General Public License
   along with Eclat.  If not, see <http://www.gnu.org/licenses/>. */

#include "libeclat.h"
#include <grecs.h>
#include <grecs-locus.h>
#include "forlangrm.h"
#include "forlan.h"

static int yyerror(char *);
union forlan_node *forlan_parse_tree;
%}
%error-verbose
%locations

%union {
	char *string;
	union forlan_node *node;
	struct grecs_list *list;
};

%token <string> STRING IDENT
%token LAST IF ELSE

%left OR
%left AND
%left NOT

%type <node> stmt stmt_cond stmt_expr stmt_blk cond bool node comp funcall arg
%type <list> stmtlist complist arglist
%type <string> string

%%
input     : stmtlist
            {
		    forlan_parse_tree = forlan_stmt_from_list($1);
	    }
          ;

stmtlist  : stmt
            {
		    $$ = forlan_stmt_list();
		    grecs_list_append($$, $1);
	    }
          | stmtlist stmt
	    {
		    grecs_list_append($1, $2);
		    $$ = $1;
	    }
          ;

stmt      : stmt_cond
          | stmt_expr
          | stmt_blk
          ;

stmt_blk  : '{' stmtlist '}'
            {
		    $$ = forlan_stmt_from_list($2);
	    }
          ;

stmt_cond : IF cond stmt
            {
		    $$ = forlan_node_create(forlan_type_cond);
		    $$->cond.expr = $2;
		    $$->cond.iftrue = $3;
		    $$->cond.iffalse = NULL;
	    }
          | IF cond stmt ELSE stmt
            {
		    $$ = forlan_node_create(forlan_type_cond);
		    $$->cond.expr = $2;
		    $$->cond.iftrue = $3;
		    $$->cond.iffalse = $5;
	    }
          ;

cond      : bool
          ;

bool      : node
            {
		    $$ = forlan_node_create(forlan_type_expr);
		    $$->expr.opcode = forlan_opcode_node;
		    $$->expr.arg[0] = $1;
	    }
          | bool AND bool
            {
		    $$ = forlan_node_create(forlan_type_expr);
		    $$->expr.opcode = forlan_opcode_and;
		    $$->expr.arg[0] = $1;
		    $$->expr.arg[1] = $3;
	    }
          | bool OR bool
            {
		    $$ = forlan_node_create(forlan_type_expr);
		    $$->expr.opcode = forlan_opcode_or;
		    $$->expr.arg[0] = $1;
		    $$->expr.arg[1] = $3;
	    }
          | NOT bool
            {
		    $$ = forlan_node_create(forlan_type_expr);
		    $$->expr.opcode = forlan_opcode_not;
		    $$->expr.arg[0] = $2;
	    }
          | '(' bool ')'
            {
		    $$ = $2;
	    }
          ;

node      : complist
            {
		    $$ = forlan_node_create(forlan_type_comp);
		    $$->comp.abs = 0;
		    $$->comp.node = forlan_stmt_from_list($1);
	    }
          | '.' complist
            {
		    $$ = forlan_node_create(forlan_type_comp);
		    $$->comp.abs = 1;
		    $$->comp.node = forlan_stmt_from_list($2);
	    }
          | LAST
            {
		    $$ = forlan_node_create(forlan_type_last);
	    }
          ;

complist  : comp
            {
		    $$ = forlan_stmt_list();
		    grecs_list_append($$, $1);
	    }
          | complist '.' comp
	    {
		    grecs_list_append($1, $3);
		    $$ = $1;
	    }
          ;

comp      : IDENT
            {
		    $$ = forlan_node_create(forlan_type_lit);
		    $$->lit.string = $1;
	    }
          | IDENT '[' string ']'
            {
		    $$ = forlan_node_create(forlan_type_test);
		    $$->test.comp = $1;
		    $$->test.value = $3;
	    }
          | funcall
          ;

string    : IDENT
          | STRING
          ;

funcall   : IDENT '(' ')'
            {
		    $$ = forlan_node_create(forlan_type_func);
		    $$->func.fp = $1; //FIXME
		    $$->func.args = NULL;
	    }
          | IDENT '(' arglist ')'
            {
		    $$ = forlan_node_create(forlan_type_func);
		    $$->func.fp = $1; //FIXME
		    $$->func.args = $3;
	    }
          ;

arglist   : arg
            {
		    $$ = forlan_stmt_list();
		    grecs_list_append($$, $1);
	    }
          | arglist ',' arg
	    {
		    grecs_list_append($1, $3);
		    $$ = $1;
	    }
          ;

arg       : node
          | STRING
            {
		    $$ = forlan_node_create(forlan_type_lit);
		    $$->lit.string = $1;
	    }
          ;

stmt_expr : funcall ';'
          ;
%%
static int
yyerror(char *s)
{
	grecs_error(&yylloc, 0, "%s", s);
	return 0;
}
	
int
forlan_parser()
{
	yydebug = debug_level(forlan_dbg) >= FORLAN_DBG_GRAM;
	return yyparse();
}

int
forlan_parse(const char *input, size_t length, struct grecs_locus_point *pt)
{
	int rc;
	forlan_lex_begin(input, length, pt);
	rc = forlan_parser();
	forlan_lex_end();
	return rc;
}

		

Return to:

Send suggestions and report system problems to the System administrator.