summaryrefslogtreecommitdiffabout
path: root/lex.l
blob: e197957cb2aae147928104c59e46ad6e45bf793f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
%{
/* ckaliases - verify syntax of sendmail-style alias files
   Copyright (C) 2005, 2007 Sergey Poznyakoff

   This program is free software; you can redistribute it and/or modify it
   under the terms of the GNU General Public License as published by the
   Free Software Foundation; either version 3 of the License, or (at your
   option) any later version.

   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License along
   with this program. If not, see <http://www.gnu.org/licenses/>. */
	
#include "alck.h"
#include "y.tab.h"	
	
static void line_begin (void);
static void line_add (char *text, size_t len);
static void line_add_unescape (char *text, size_t len);
static void line_finish (void);

static SLIST *slist;
 
char *file_name;
int line_num;
 
%}


%x STR
IDENT [a-zA-Z0-9_\-+\./]+
WS [ \t]
SPEC [:@\\]
%%
  /* Comments */
#.*\n   { line_num++; return EOL; }
  /* White space */
^{WS}+\n { line_num++; return EOL; }
{WS}+    ;
  /* Names and emails */
:include:  return INCLUDE;
^{IDENT}  {
	  line_begin();
          line_add(yytext, yyleng);
          line_finish ();
	  return LHS; }
{IDENT}@{IDENT} {
	  line_begin();
          line_add(yytext, yyleng);
          line_finish();
	  return EMAIL; }
{IDENT} { line_begin();
          line_add(yytext, yyleng);
          line_finish();
	  return IDENT; }
  /* Quoted strings */
\"[^\\"\n]*\"   { line_begin();
                  line_add(yytext, yyleng);
                  line_finish();
                  return STRING; }
\"[^\\"\n]*\\.    { BEGIN(STR);
                   line_begin();
		   line_add_unescape(yytext + 1, yyleng - 1); }
<STR>[^\\"\n]*\\. { line_add_unescape(yytext, yyleng); }
<STR>[^\\"\n]*\" { BEGIN(INITIAL);
                   if (yyleng > 1) 
                     line_add(yytext, yyleng - 1); 
                   line_finish();
		   return STRING; }
  /* Other characters */
{SPEC}  return yytext[0];
\\\n    { line_num++; }
\n{WS}+/[^ \t\n]  { line_num++; return CONT; }
\n      { line_num++; return EOL; }
,	return yytext[0];
.       { error_at_line(0, 0, file_name, line_num, 
			 "Stray character %03o in alias file", yytext[0]);
          error_count++; }
%%

int
yywrap()
{
	fclose(yyin);
	free(file_name);
	file_name = NULL;
	return 1;
}

static char escape_transtab[] = "\\\\a\ab\bf\fn\nr\rt\t";

int
unescape_char(int c)
{
	char *p;
	
	for (p = escape_transtab; *p; p += 2) {
		if (*p == c)
			return p[1];
	}
	return c;
}

void
line_add(char *text, size_t len)
{
	slist_add_n(&slist, text, len);
}

void
line_add_unescape(char *text, size_t len)
{
	char c;
	char *p;
	
	p = slist_add_n(&slist, text, len);
	p[len - 1] = unescape_char(text[len - 1]);
}

void
line_begin()
{
	slist_destroy(&slist);
}

void
line_finish()
{
	size_t len = 0;
	struct string_list *sp;
	char *p;
	
	for (sp = slist->head; sp; sp = sp->next)
		len += sp->len;
	yylval.string = emalloc(len + 1);
	p = yylval.string;
	for (sp = slist->head; sp; sp = sp->next) {
		memcpy(p, sp->str, sp->len);
		p += sp->len;
	}
	*p = 0;
}

void
openaliases(char *name)
{
	yyin = fopen(name, "r");
	if (!yyin) {
		syserror(errno, "cannot open file `%s'", name);
		exit(1);
	}
	file_name = strdup(name);
	line_num = 0;
}

void
openaliases_prefix(char *prefix, char *name)
{
	char *fullname = NULL;
	struct stat st;
	
	if (stat(prefix, &st)) {
		syserror(errno, "cannot stat `%s'", prefix);
		exit(1);
	}

	if (!S_ISDIR(st.st_mode)) {
		char *p = strrchr(prefix, '/');
		if (p)
			*p = 0;
		else
			prefix = ".";
	}
	fullname = emalloc(strlen(prefix) + strlen(name) + 2);
	strcpy(fullname, prefix);
	strcat(fullname, "/");
	strcat(fullname, name);
	openaliases(fullname);
	free(fullname);
}

void
init_lex()
{
	yy_flex_debug = 0;
}

void
lex_debug(int debug)
{
	yy_flex_debug = debug;
}

void
freadlist(SLIST **plist, char *name)
{
	char *p;
	char buffer[256];
	FILE *fp;
	int line = 0;
	int skipeol = 0;

	fp = fopen(name, "r");
	if (!fp) {
		parserror(file_name, line_num,
			  "cannot open include file `%s': %s",
			  name, strerror(errno));
		error_count++;
		return;
	}

	while (p = fgets(buffer, sizeof buffer, fp)) {
		size_t len = strlen(p);

		line++;
		
		if (len == 0)
			continue;
		if (p[len-1] != '\n') {
			if (!feof(fp)) {
				if (!skipeol)
					parserror(name, line,
						  "line too long");
				error_count++;
				skipeol = 1;
			}
		} else if (skipeol)
			continue;
		else {
			p[--len] = 0;
			skipeol = 0;
		}

		while (*p && isspace(*p))
			p++;
		if (!*p || *p == '#')
			continue;

		slist_add(plist, p);
	}
	fclose(fp);
}

void
preadlist(SLIST **plist, char *progname)
{
	char *p;
	char buffer[256];
	FILE *fp;
	int line = 0;
	int skipeol = 0;

	fp = popen(progname, "r");
	if (!fp) {
		parserror(file_name, line_num,
			  "cannot run `%s': %s",
			  progname, strerror(errno));
		error_count++;
		return;
	}
	
	while (p = fgets(buffer, sizeof buffer, fp)) {
		size_t len = strlen(p);
		char *q;

		line++;
		
		if (len == 0)
			continue;
		if (p[len-1] != '\n') {
			if (!feof(fp)) {
				if (!skipeol)
					parserror(progname, line,
						  "line too long");
				error_count++;
				skipeol = 1;
			}
		} else if (skipeol)
			continue;
		else {
			p[--len] = 0;
			skipeol = 0;
		}

		if (!*p || !isalnum(*p) || p[strcspn(p, " \t")])
			continue;
		
		slist_add(plist, p);
	}
	pclose(fp);
}	

Return to:

Send suggestions and report system problems to the System administrator.