aboutsummaryrefslogtreecommitdiff
path: root/lex.l
blob: dfb1793051b41abb8014cc5363746f4b81a555f4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
%{
/* ckaliases - verify syntax of sendmail-style alias files
   Copyright (C) 2005 Sergey Poznyakoff

   This program is free software; you can redistribute it and/or modify
   it under the terms of the GNU General Public License as published by
   the Free Software Foundation; either version 2 of the License, or
   (at your option) any later version.

   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License
   along with this program; if not, write to the Free Software
   Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
   02110-1301 USA. */
	
#include <stdio.h>
#include <stdlib.h>
#include <unistd.h>  
#include <sys/file.h>
#include <sys/stat.h>
#include <errno.h>
#include <string.h>
#define obstack_chunk_alloc malloc
#define obstack_chunk_free free	
#include <obstack.h>
#include "ckaliases.h"
#include "gram.h"	
	
static void line_begin(void);
static void line_add(char *text, size_t len);
static void line_add_unescape(char *text, size_t len);
static void line_finish(void);

struct obstack string_stk;
 
char *file_name;
int line_num;
 
%}


%x STR
IDENT [a-zA-Z0-9_\-+\./]+
WS [ \t]
SPEC [:@\\]
%%
  /* Comments */
#.*\n   { line_num++; return EOL; }
  /* White space */
^{WS}+\n { line_num++; return EOL; }
{WS}+    ;
  /* Names and emails */
:include:  return INCLUDE;
^{IDENT}  {
	  line_begin();
          line_add(yytext, yyleng);
          line_finish();
	  return LHS; }
{IDENT}@{IDENT} {
	  line_begin();
          line_add(yytext, yyleng);
          line_finish();
	  return EMAIL; }
{IDENT} { line_begin();
          line_add(yytext, yyleng);
          line_finish();
	  return IDENT; }
  /* Quoted strings */
\"[^\\"\n]*\"   { line_begin();
                  line_add(yytext, yyleng);
                  line_finish();
                  return STRING; }
\"[^\\"\n]*\\.    { BEGIN(STR);
                   line_begin();
		   line_add_unescape(yytext + 1, yyleng - 1); }
<STR>[^\\"\n]*\\. { line_add_unescape(yytext, yyleng); }
<STR>[^\\"\n]*\" { BEGIN(INITIAL);
                   if (yyleng > 1) 
                     line_add(yytext, yyleng - 1); 
                   line_finish();
		   return STRING; }
  /* Other characters */
{SPEC}  return yytext[0];
\\\n    { line_num++; }
\n{WS}+/[^ \t\n]  { line_num++; return CONT; }
\n      { line_num++; return EOL; }
,	return yytext[0];
.       { char *p;
          asprintf(&p,
		   "Stray character %03o in alias file", yytext[0]);
          yyerror(p);
  	  free (p); }
%%

int
yywrap()
{
	fclose(yyin);
	return 1;
}

static char escape_transtab[] = "\\\\a\ab\bf\fn\nr\rt\t";

int
unescape_char (int c)
{
  char *p;

  for (p = escape_transtab; *p; p += 2)
    {
      if (*p == c)
	return p[1];
    }
  return c;
}

void
line_add(char *text, size_t len)
{
	obstack_grow(&string_stk, text, len);
}

void
line_add_unescape(char *text, size_t len)
{
	char c;
	obstack_grow(&string_stk, text, len - 2);
	c = unescape_char(text[len - 1]);
	obstack_1grow(&string_stk, c);
}

void
line_begin()
{
}

void
line_finish()
{
	obstack_1grow(&string_stk, 0);
	yylval.string = obstack_finish(&string_stk);
}

void
openaliases(char *name)
{
	yyin = fopen(name, "r");
	if (!yyin) {
		fprintf(stderr, "cannot open file `%s': %s\n",
			name, strerror(errno));
		exit(1);
	}
	file_name = name;
	line_num = 0;
}

void
openaliases_prefix(char *prefix, char *name)
{
	char *fullname = NULL;
	struct stat st;
	
	if (stat(prefix, &st)) {
		fprintf(stderr, "cannot stat `%s': %s\n",
			prefix, strerror(errno));
		exit(1);
	}

	if (!S_ISDIR(st.st_mode)) {
		char *p = strrchr(prefix, '/');
		if (p)
			*p = 0;
		else
			prefix = ".";
	}
	asprintf(&fullname, "%s/%s", prefix, name);
	openaliases(fullname);
	free(fullname);
}

void
init_lex()
{
	obstack_init(&string_stk);
	yy_flex_debug = 0;
}

void
lex_debug(int debug)
{
	yy_flex_debug = debug;
}

void
read_include(SLIST **plist, char *name)
{
	char *p;
	char buffer[256];
	FILE *fp = fopen(name, "r");

	if (!fp) {
		char *p;
		asprintf(&p,
			 "cannot open include file `%s': %s",
			 name, strerror(errno));
		yyerror(p);
		free(p);
		return;
	}

	while (p = fgets(buffer, sizeof buffer, fp)) {
		char *q;
		
		while (*p && isspace(*p))
			p++;
		if (*p == '#')
			continue;
		for (q = p + strlen(p) - 1; q > p && isspace(*q); q--)
			;
		q[1] = 0;
		if (*p) 
			slist_add(plist, strdup(p));
	}
	fclose(fp);
}
	

Return to:

Send suggestions and report system problems to the System administrator.