summaryrefslogtreecommitdiffabout
path: root/acmeman
blob: 0a51cdbe32711edec074b1fd0bbd7859d8856a06 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
#!/bin/sh
#! -*-perl-*-
eval 'exec perl -x -wS $0 ${1+"$@"}'
    if 0;
# Copyright (C) 2017, 2018 Sergey Poznyakoff <gray@gnu.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3, or (at your option)
# any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.
use strict;
use feature 'state';
use Protocol::ACME;
use Protocol::ACME::Challenge::LocalFile;
use Crypt::Format;
use Crypt::OpenSSL::PKCS10 qw(:const);
use Crypt::OpenSSL::RSA;
use Crypt::OpenSSL::X509;
use File::Basename;
use File::Path qw(make_path);
use DateTime::Format::Strptime;
use LWP::UserAgent;
use LWP::Protocol::https;
use Socket qw(inet_ntoa);
use Sys::Hostname;
use Pod::Usage;
use Pod::Man;
use Getopt::Long qw(:config gnu_getopt no_ignore_case);
use POSIX qw(strftime time floor);
use App::Acmeman::Config;
use App::Acmeman::Domain qw(:files);
use Data::Dumper;
use Text::ParseWords;

our $VERSION = '1.05';

=head1 NAME

App::Acmeman - manages ACME certificates

=head1 SYNOPSIS

B<acmeman>
[B<-Fadns>]
[B<-D> I<N>]
[B<-f> I<FILE>]    
[B<--alt-names>]
[B<--config-file=>I<FILE>]
[B<--debug>]
[B<--dry-run>]
[B<--force>]
[B<--stage>]    
[B<--time-delta=>I<N>]
[I<DOMAIN>...]
    
B<acmeman> B<--setup> | B<-S>
[B<-Fdn>]
[B<--config-file=>I<FILE>]
[B<--debug>]
[B<--dry-run>]
[B<--force>]

B<acmeman>
[B<-h>]
[B<--help>]
[B<--usage>]
    
=head1 DESCRIPTION

A tool for automatic creation and renewal of ACME (LetsEncrypt) SSL
certificates. The list of domains to handle can be obtained from
B<acmeman> or B<apache> configuration files, or from both. If the
default B<acmeman> configuration file doesn't exist, the program
scans B<apache> configuration files for a list of domains.

B<Acmeman> is normally run periodically as a cronjob.
    
If you plan to serve SSL protected domains using apache, you can skip
right to the B<apache> section.

The following is a short introduction to the B<acmeman> configuration. For
a detailed discussion, see the B<CONFIGURATION> section below.

The configuration file, B</etc/acmeman.conf>, consists of statements,
which have the form B<I<KW>=I<VAL>>, grouped into sections, declared
as B<[I<NAME>]> (square brackets are part of the syntax). Empty lines
and comments (introduced by a hash sign) are ignored.

Domains which require LetsEncrypt certificates are declared in B<domain>
section. Each section introduces a single domain. E.g.:

    [domain example.com]
        alt = www.example.com
        files = default
    
This section instructs B<acmeman> that a certificate is needed for
domain B<example.com>, using B<www.example.com> as its alternative name,
The B<files> statement identifies the name of a B<files> section containing
rules for creating certificate files for that domain. This section must be
defined elsewhere in the configuration file. For example:

    [files default]
        type = split
        certificate-file = /etc/ssl/acme/$domain/cert.pem
        key-file = /etc/ssl/acme/$domain/privkey.pem
        ca-file = /etc/ssl/acme/$domain/ca.pem
        argument = $domain
    
This definition tells B<acmeman> that it should store certificate, certficate
key, and certificate authority chain in three separate files. Names of these
files will be created by replacing the B<$domain> string in the corresponding
definition with the domain name from the B<domain> section,

In fact, the B<files> section above is the default one. It will be created
implicitly if no other B<files> section is defined in the configuration file.
Moreover, the string B<default> is the default identifier, which is used if
the B<domain> section lacks the B<files> keyword.

The special section B<[core]> contains basic settings that control the
program behavior. One of the important settings is B<source>, which declares
an external source from which domain settings must be obtained. As
of B<acmeman> version 1.05, the following sources are available:
B<null>, B<apache>, and B<file>.
    
Consider the following configuration:

    [core]
        source = apache

It instructs B<acmeman> to read domain settings from Apache configuration
files. This is basically the configuration that is used in the absense of
the configuration file. See the B<APACHE> section for a detailed discussion
of this operation mode.    
    
=head1 CONFIGURATION

Configuration file controls the operation of B<acmeman>. By default,
its name is B</etc/acmeman.conf>. If it is absent, B<acmeman> falls
back to the legacy operation mode, scanning Apache configuration files
for domains that use LetsEncrypt SSL certificates. See the B<APACHE>
section below for a detailed description.    

The configuration file has a traditional line-oriented syntax. Comments
are introduced with a hash sign. Empty lines are ignored. Leading and
trailing whitespace is removed prior to parsing. Long statements can be
split over several physical lines by ending each line excepting the last
one with a backslash immediately followed by a newline character.
    
Statements have the following syntax:

    KEYWORD = VALUES

where I<KEYWORD> stands for a symbolic name consisting of alphanumeric
characters, dashes and underscores, and I<VALUE> stands for any sequence
of characters.

Statements are grouped in sections. Each section is identified by its name
and optional arguments. The section begins with the construct

    [NAME]

or, if arguments are present:
    
    [NAME ARG1 ARG2 ...]

The square brackets are part of the syntax.

The statements in the configuration file form a directed graph. Often
in this document we will identify the statement by its I<path>, i.e. a
list of section name, arguments and the keyword, separated by dots. For
example, the path B<files.apache.type> corresponds to the following
configuration file fragment:

    [files apache]
       type = single

The following describes the available sections and keywords

=head2 B<[core]>

This section defines the behavior of the program as a whole.

=over 4

=item B<rootdir=>I<DIR>

Defines the root directory to use instead of the default </var/www/acme>.
Root directory is the directory under which the
F<.well-known/acme-challenge> subdirectory is located.

=item B<time-delta=>I<SECONDS>
 
Sets the time window before the actual expiration time, when the certificate
becomes eligible for renewal.  I<N> is time in seconds.  The default
value is 86400, which means that B<acmeman> will attempt to renew any
certificate that expires within 24 hours.     

The command line option B<--time-delta> overrides this setting.

=item B<postrenew=>I<COMMAND>

Defines the command to be run at the end of the run if at least one
certificate has been updated. Normally this command reloads the httpd
server (or whatever server is using the certificates). If more than one
B<postrenew> statements are defined, they will be run in sequence, in the
same order as they appeared in the configuration file.

=item B<source=>I<ID> [I<ARG>...]

Defines additional source of information. B<App::Acmeman> version 1.05
is shipped with three sources: B<null>, B<apache>, and B<file>. 

The B<null> module is an empty source. Command line arguments are ignored.
Use this source if all domains are described in the configuration file.

The B<apache> source module is the default. It scans B<httpd> configuration
files as described in section B<APACHE>. One argument is allowed. If supplied,
it defines the apache configuration layout. Allowed values are: B<debian>,
B<slackware>, B<suse> and B<rh> (for Red Hat). Without arguments, the layout
will be autodetected.

The B<file> source reads domain names from one or more disk files. A
mandatory argument specifies the name of the directory where the files
are located. This mode is suitable for use with B<haproxy> pattern files.
    
=item B<files=>I<NAME>

Identifies the B<[files]> section which describes how to create certificate
files for domains which lack explicit B<files> keyword. Default I<NAME> is
B<default>. See the description of the B<files> statement in B<domain>
section.    

=item B<check-alt-names=>I<BOOL>

When set to B<true>, it instructs the program to compare the list of
alternative names of each certificate with the one gathered from the
Apache configuration, and reissue the certificate if the two lists
don't match.  This uses an ad-hoc logic, due to the deficiency of the
underlying X509 module, and therefore is not enabled by default.

Valid values for I<BOOL> are: B<1>, B<on>, B<true>, or B<yes>, for
true, and B<0>, B<off>, B<false>, or B<no> for false (all values
case-insensitive).    

=item B<check-dns=>I<BOOL>

When set to B<true> (the default), the program will check whether each
host name has an A DNS record pointing back to one of the IP addresses
of the server. Hostnames which don't satisfy this condition will be ignored.
The IP of the server is determined by looking up the A record for its
hostname. This can be overridden using the B<my-ip> configuration statement.
    
=item B<key-size=>I<N>

Size of the RSA key to use, in bits. Default is 4096.

=item B<my-ip>=I<IP> [I<IP>...]

Declares IP address (or addresses) of this server. Use this keyword if
the server IP cannot be reliably determined by resolving its hostname.
Special I<IP> B<$hostip> stands for the IP retreived by resolving the
hostname.
    
=back

=head2 B<[domain I<CN>]>

Declares the domain for which a certificate should be maintained. I<CN> is
the canonical name for the domain. Alternative names can be specified using
the B<alt> keyword.    
    
=over 4

=item B<files=>I<ID>

Identifies the B<[files]> section which describes how to create certificate
files for this domain. In the absense of this statement, the B<files>
statement from the B<[core]> section will be used.
    
=item B<alt=>I<NAME>

Defines alternative name for the certificate. Multiple B<alt> statements
are allowed.    

=item B<key-size=>I<N>

Size of the RSA key to use, in bits. If not set, the B<core.key-size>
setting is used.    

=item B<postrenew=>I<CMD>

Run I<CMD> after successful update. If not given, the B<core.postrenew>
commands will be run.    
    
=back
    
=head2 B<[files I<ID>]>

The B<files> section instructs B<acmeman> how to create certificate files.
It is applied to particular domains by placing the B<files=I<ID>> statement
in the coresponding domain sections.

The I<FILENAME> arguments to the keywords below can contain references to
a I<meta-variable>, which will be replaced by the actual domain name when
handling this section for a particular domain. By default, this meta-variable
is B<$domain>.     
    
=over 4
    
=item B<type=>B<single>|B<split>

Type of the certificate to create. When set to B<single>, a single
certificate file will be created. Its name is determined by the
B<certificate-file> statement. The file will contain the certificate,
certificate chain and the signature, in this order.

When set to B<split>, the certificate, certificate chain and the signature
will be saved to three distinct files, whose names are defined by
B<certificate-file>, B<ca-file>, and B<key-file>, correspondingly. If     
B<ca-file> is not defined, only certificate and key files will be created.

The default is B<split>.
    
=item B<certificate-file=>I<FILENAME>

Defines the name of the certificate file for this domain. This statement
is mandatory.    
    
=item B<key-file=>I<FILENAME>

Defines the name of the certificate key file. This statement must be present
if B<type> is set to B<split>.    
    
=item B<ca-file=>I<FILENAME>

Defines the name of the certificate authority file. This statement may
be present if B<type> is set to B<split>.    
    
=item B<argument=>I<STRING>

Defines the name of the meta-variable in I<FILENAME> arguments, which will
be replaced with the actual domain name. Default is B<$domain>.    
    
=back

=head1 SOURCES

=head2 null

    [core]
        source = null

Declares empty source. This means that B<acmeman> will handle only domain
names explicitly declared in the configuration file using the B<domain>
setting.
    
=head2 apache

    [core]
        source = apache [LAYOUT]
    
This is the default source. It assumes Apache httpd, version 2.4 or later
(although only minor changes are necessary to make it work with version 2.2).
The optional I<LAYOUT> argument defines the layout of the apache configuration
files. Allowed layout values are: B<debian>, B<slackware>, B<suse> and
B<rh> (for Red Hat). If not supplied, the layout is determined automatically.

A special directory should be configured for receiving ACME challenges. 

The package provides two Apache macros: for serving ACME challenges and
declaring SSL virtual hosts.    
    
Upon startup the program scans Apache configuration for virtual hosts
that use ACME certificates, checks their expiration times, and renews those
of the certificates that are nearing their expiration times within a
predefined number of seconds (24 hours by default).  If any of the
certificates were updated during the run, B<acmeman> will restart the
B<httpd> server.    

=head3 Setup    

To set up the necessary infrastructure, run B<acmeman --setup>.  It will
create the configuration file B<httpd-letsencrypt.conf>, defining two
macros for SSL-enabled sites (B<mod_macro> is needed).  Finally, it will
create the directory B</var/www/acme>, which will be used for receiving
and serving ACME challenges.  If another directory is preferred, it can
be specified as an argument to B<acmeman --setup>.

The tool will try to determine the layout of the Apache configuration
files and place the created file accordingly, so that it will be included
into the main configuration file.  It will print the name of the created
file at the end of the run.  You are advised to ensure that the file is
included and that the module B<mod_macro> is loaded prior to it.  You
may also wish to revise B<httpd-letsencrypt.conf> and edit the paths to
SSL files configured there.  By default, the directory F</etc/acme/I<DOMAIN>>
will be created for each domain name needing SSL, and two files will be placed
there: F<cert.pem>, containing the leaf and intermediate certificates for that
domain, and F<privkey.pem>, containing the private key for that domain.    

The program will refuse to overwrite existing files B<httpd-letsencrypt.conf>,
unless given the B<--force> (B<-F>) option.

=head3 Configuring SSL
    
To declare that a virtual host needs SSL certificate, add the following
line to the Apache B<VirtualHost> block serving plain HTTP for that host:

    Use LetsEncryptChallenge

This will instruct B<acmeman> to request a certificate for that virtual
host.  The hostname declared with the B<ServerName> statement will be used
as the B<CN> for the certificate, and any names declared via B<ServerAlias>
statements will form the list of alternative names (obviously, wildcards are
not allowed).

If such a certificate doesn't exist, it will be requested and created when
B<acmeman> is run.

To use the created certificate, create a new B<VirtualHost> block that
contains the following statement:    

    Use LetsEncryptServer DOMAIN

where I<DOMAIN> is the name used in the B<ServerName> statement of the plain
HTTP configuration.  Copy the B<ServerAlias> statements (if any), and add the
rest of configuration statements.  Note, that you need not use the
B<ServerName> statement, as it will be included when the B<LetsEncryptServer>
macro is expanded.

Example:

    <VirtualHost *:80>
        ServerName example.org
        ServerAlias www.example.com
        Use LetsEncryptChallenge
        ...
    </VirtualHost>

    <VirtualHost *:443>
        Use LetsEncryptServer example.org
        ServerAlias www.example.com
        ...
    </VirtualHost>

Alternatively, you can use the B<LetsEncryptSSL> macro, which differs from
B<LetsEncryptServer> in that it configures only SSL settings, without the
B<ServerName> statement, which therefore must be included explicitly:    
    
    <VirtualHost *:443>
        ServerName example.org
        ServerAlias www.example.com
        Use LetsEncryptSSL example.org
        ...
    </VirtualHost>

LetsEncrypt limits the number of certificates requested for a single
registered domain per week (at the time of this writing - 20).  To avoid
hitting that limit, you may wish to use the same certificate for different
virtual hosts.  The special macro B<LetsEncryptReference> is provided for
that purpose.  Suppose, for example, that you wish to configure server
name B<git.example.org> to use the same certificate as B<example.org>
(configured in the example above).  You then declare the virtual host
for the plain HTTP as follows:    

    <VirtualHost *:80>
        ServerName git.example.org
        Use LetsEncryptReference example.org
        ...
    </VirtualHost>

The argument to the B<LetsEncryptReference> macro indicates the CN name of
the certificate to which the current server name (and aliases, if any) are
to be added as alternative names.  The corresponding virtual host for SSL
will use the B<LetsEncryptSSL> macro to configure the correct certificate:    

    <VirtualHost *:80>
        ServerName git.example.org
        Use LetsEncryptSSL example.org
        ...
    </VirtualHost>

=head2 file

    [core]
        source = file PATTERN [--ignore=RX] [--host=HOST]

Domain names will be read from files matching I<PATTERN>. This argument
can be either a valid globbing pattern or a directory name. In the latter
case, the source module will read all files from that directory, except
those whose names match the following perl regexp: C<^\.|~$|\.bak$|^#.*#$>.
The default regexp can be overridden using the B<--ignore> (B<-i>) option.

The input files must contain exactly one domain name per line. No empty
lines or comments are allowed. The first domain name will become the B<CN>
of the issued certificate. The rest of domain names will form alternative
names.

If the B<--host> (B<-h>) option is used, only one certificate will be
issued. The I<HOST> will be used as its B<CN>. All the domain names read
from the input files will form the list of its alternative names.    
    
=head1 OPTIONS

=over 4

=item B<-D>, B<--time-delta=>I<N>

Sets the time window before the actual expiration time, when the certificate
becomes eligible for renewal.  I<N> is time in seconds.  The default
value is 86400, which means that B<acmeman> will attempt to renew any
certificate that expires within 24 hours.     

This option overrides the B<core.time-delta> configuration setting.
    
=item B<-F>, B<--force>

Force renewal of certificates, no matter their expire date.  With B<--setup>,
force installing the B<httpd-letsencrypt.conf> file even if it already
exists.    

=item B<-a>, B<--alt-names>

Compare the list of alternative names of each certificate with the one
gathered from the Apache configuration, and reissue the certificate 
if the two lists don't match.  This uses an ad-hoc logic, due to the
deficiency of the underlying X509 module, and therefore is not enabled
by default.    

This option overrides the B<core.check-alt-names> configuration setting.
    
=item B<-d>, B<--debug>

Increase debugging level.  Multiple options accumulate.  Three debugging
levels are implemented:

=over 8

=item B<-d>

List certificates being renewed.
    
=item B<-dd>

List files being created.  Show basic information about ACME transactions for
each certificate.    

=item B<-ddd>

Verbosely report parsing of Apache configuration files.  Show detailed
debugging information about ACME transactions for each certificate.    
    
=back    
    
=item B<-f>, B<--config-file=>I<FILE>

Read configuration from I<FILE>, instead of the default F</etc/acmeman.conf>.
    
=item B<-n>, B<--dry-run>

Don't modify any files, just print what would have been done.
Implies B<--debug>. 

=item B<-S>, B<--setup>

Set up the B<acmeman> infrastructure files.
    
=item B<-s>, B<--stage>
    
Use LetsEncrypt staging server.
 
=back

The following options are informational:

=over 4

=item B<-h>

Prints a short usage summary.
    
=item B<--help>

Prints detailed user manual.    

=item B<--usage>

Outputs a terse reminder of the command line syntax along with a
list of available options.

=back    
    
=head1 AUTHOR

Sergey Poznyakoff <gray@gnu.org>    
    
=cut    

my $progname = basename($0);
my $progdescr = "manages ACME certificates";
my $debug = 0;
my $dry_run;
my $acme_host = 'prod';
my %acme_endpoint = (prod => 'acme-v01.api.letsencrypt.org',  
                     staging => 'acme-staging.api.letsencrypt.org');
my $letsencrypt_root_cert_url =
    'https://letsencrypt.org/certs/lets-encrypt-x3-cross-signed.pem';
my $force = 0;
my %select;               # Hash of selected domain names 

my $config_file = '/etc/acmeman.conf';
my $config;

my $account_key;
my $challenge;

use constant {
    EX_OK           => 0,
    EX_USAGE        => 64,
    EX_DATAERR      => 65,
    EX_NOINPUT      => 66,
    EX_SOFTWARE     => 70,
    EX_OSFILE       => 72,
    EX_CANTCREAT    => 73,
    EX_NOPERM       => 77,
    EX_CONFIG       => 78
};

sub error {
    my $msg = shift;
    local %_ = @_;
    print STDERR "$progname: " if defined($progname);
    print STDERR "$_{prefix}: " if defined($_{prefix});
        print STDERR "$msg\n"
}

sub debug {
    my $l = shift;
    error(join(' ',@_), prefix => 'DEBUG') if $debug >= $l;
}

sub abend {
    my $code = shift;
    print STDERR "$progname: " if defined($progname);
    print STDERR "@_\n";
    exit $code;
}

sub prep_dir {
    my $dir = dirname(shift);
    if (! -d $dir) {
	debug(3, "creating directory $dir");
	my @created = make_path("$dir", { error => \my $err } );
	if (@$err) {
	    for my $diag (@$err) {
		my ($file, $message) = %$diag;
		if ($file eq '') {
		    error($message);
		} else {
		    error("mkdir $file: $message");
		}
	    }
	    exit(EX_CANTCREAT);
	}
    }
}

sub runcmd {
    my $cmd = shift;
    debug(1, "running $cmd");
    unless ($dry_run) {
	system($cmd);
	if ($? == -1) {
	    error("$cmd: failed to execute: $!");
	} elsif ($? & 127) {
	    error("$cmd: died on signal ".($? & 127));
	} elsif (my $code = ($? >> 8)) {
	    error("$cmd: exited with code $code");
	}
    }
}

sub debug_to_loglevel {
    my @lev = ('err', 'info', 'debug');
    return $lev[$debug > $#lev ? $#lev : $debug];
}

sub make_csr {
    my ($dom, $keysize) = @_;
    my $req = Crypt::OpenSSL::PKCS10->new($keysize);
    $req->set_subject("/CN=".$dom->cn);
    $req->add_ext(Crypt::OpenSSL::PKCS10::NID_subject_alt_name,
		  join(',', map { "DNS:$_" } $dom->alt))
	if $dom->alt > 0;
    $req->add_ext_final();
    $req->sign();
    return $req;
}

sub save_crt {
    my $domain = shift;
    my $type = shift;

    if (my $filename = $domain->file($type)) {
	debug(3, "writing $filename");
	prep_dir($filename);
	open(my $fd, '>', $filename);

	foreach my $der (@_) {
	    my $pem = Crypt::Format::der2pem($der, 'CERTIFICATE');
	    print $fd $pem;
	    print $fd "\n";
	}
	close $fd;
	return $filename;
    }
}

sub selected_domain {
    my $dom = shift;
    return 1 unless %select;
    return grep { $select{$_} } $dom->names;
}

sub domain_cert_expires {
    my $domain = shift;
    my $crt = $domain->certificate_file;
    if (-f $crt) {
	my $x509 = Crypt::OpenSSL::X509->new_from_file($crt);

	my $exts = $x509->extensions_by_name();
	if (exists($exts->{subjectAltName})) {
	    my $msg = $config->get(qw(core check-alt-names))
		        ? 'will renew' : 'use -a to trigger renewal';
	    my @names = map { s/^DNS://; $_ } 
                          split /,\s*/, $exts->{subjectAltName}->to_string();
	    my @missing;
	    foreach my $vh (sort { length($b) <=> length($a) } $domain->names) {
                unless (grep { $_ eq $vh } @names) {
		    push @missing, $vh;
		}
	    }
	    if (@missing) {
		debug(1, "$crt: the following SANs are missing: "
		      . join(', ', @missing)
		      ."; $msg");
		return 1 if $config->get(qw(core check-alt-names));
	    }
	}
	    
	my $expiry = $x509->notAfter();

	my $strp = DateTime::Format::Strptime->new(
	    pattern => '%b %d %H:%M:%S %Y %Z',
	    time_zone => 'GMT'
	);
	my $ts = $strp->parse_datetime($expiry)->epoch;
	my $now = time();
	if ($now < $ts) {
	    my $hours = floor(($ts - $now) / 3600);
	    my $in;
	    if ($hours > 24) {
		my $days = floor($hours / 24);
		$in = "in $days days";
	    } elsif ($hours == 24) {
		$in = "in one day";
	    } else {
		$in = "today";
	    }
	    debug(2, "$crt expires on $expiry, $in");
	    if ($now + $config->get(qw(core time-delta)) < $ts) {
		return 0;
	    } else {
		debug(2, "will renew $crt (expires on $expiry, $in)");
	    }
	} else {
	    debug(2, "will renew $crt");
	}
    }
    return 1;
}

sub register_domain_certificate {
    my $domain = shift;
    
    my $key_size = $config->get('domain', $domain, 'key-size')
	            || $config->get('core', 'key-size');

    if ($debug) {
	my $crt = $domain->certificate_file;
	my $alt = join(',', $domain->alt);
	if (-f $crt) {
	    debug(1, "renewing $crt: CN=$domain, alternatives=$alt, key_size=$key_size");
	} else {
	    debug(1, "issuing $crt: CN=$domain, alternatives=$alt, key_size=$key_size");
	}
    }

    return 1 if $dry_run;
    $account_key = Crypt::OpenSSL::RSA->generate_key($key_size);

    my $acme = Protocol::ACME->new(
    	host => $acme_endpoint{$acme_host},
    	account_key => { buffer => $account_key->get_private_key_string(), format => 'PEM' },
    	loglevel => debug_to_loglevel()
    );

    eval {
	$acme->directory();
	$acme->register();
	$acme->accept_tos();

        foreach my $name ($domain->names) {
   	    $acme->authz($name);
  	    $acme->handle_challenge($challenge);
	    $acme->check_challenge();
	    $acme->cleanup_challenge($challenge);
        }

	my $csr = make_csr($domain, $key_size);
        my $cert = $acme->sign({ format => 'PEM', buffer => $csr->get_pem_req() });
        my $chain = $acme->chain();

        if (my $filename = $domain->file(KEY_FILE)) {
	    debug(3, "writing $filename");
	    prep_dir($filename);
	    my $u = umask(077);
	    $csr->write_pem_pk($filename);
	    umask($u);

            if ($filename = $domain->file(CA_FILE)) {
                save_crt($domain, CA_FILE, $chain);
            }
            save_crt($domain, CERT_FILE, $cert);
        } else {
            $filename = $domain->certificate_file;
	    debug(3, "writing $filename");
	    prep_dir($filename);
	    my $u = umask(077);
            open(my $fd, '>', $filename)
		or abend(EX_CANTCREAT, "can't open $filename for writing: $!");
	    print $fd Crypt::Format::der2pem($cert, 'CERTIFICATE');
	    print $fd "\n";
	    print $fd Crypt::Format::der2pem($chain, 'CERTIFICATE');
	    print $fd "\n";
	    print $fd $csr->get_pem_pk();
	    print $fd "\n";
	    umask($u);
	}
    };
    if ($@) {
    	if (UNIVERSAL::isa($@, 'Protocol::ACME::Exception')) {
    	    error("$domain: can't renew certificate: $@->{status}");
            if (exists($@->{error})) {
    	        error("$domain: $@->{error}{status} $@->{error}{detail}");
    	    } else {
    	        error("$domain: $@->{detail} $@->{type}");
            }
        } elsif (ref($@) == '') {
            chomp $@;
            error("$domain: failed to renew certificate: $@");
    	} else {
            error("$domain: failed to renew certificate");
            print STDERR Dumper([$@]);
    	}
        return 0;  
    }
    return 1;
}

sub get_root_cert {
    my $name = shift;

    prep_dir($name) unless $dry_run;

    debug(1, "downloading $letsencrypt_root_cert_url to \"$name\"");
    my $ua = LWP::UserAgent->new;
    my $response = $ua->get($letsencrypt_root_cert_url);
    if ($response->is_success) {
	unless ($dry_run) {
	    open(my $fd, '>', $name)
		or abend(EX_CANTCREAT, "can't open \"$name\" for writing: $!");
	    print $fd $response->decoded_content;
	    close $fd;
	}
    } else {
	error("error downloading certificate from $letsencrypt_root_cert_url");
	abend(EX_NOINPUT, $response->status_line);
    }
}

sub initial_setup {
    get_root_cert('/etc/ssl/acme/lets-encrypt-x3-cross-signed.pem');
    my $source = $config->get(qw(core source));
    unless (defined($source)) {
	require App::Acmeman::Source::Apache;
	$source = new App::Acmeman::Source::Apache;
	$source->configure($config);
	$source = undef unless $config->success;
	$config->clrerr;
    }

    if ($source) {
	unless ($source->setup(dry_run => $dry_run, force => $force)) {
	    exit(1);
	}
    }

    exit(EX_OK);
}

sub coalesce {
    my $ref = shift;
    debug(2, "coalescing virtual hosts");
    my $i = 0;
    my @domlist;
    foreach my $ent (sort { $a->{domain} cmp $b->{domain} }
		     map { { ord => $i++, domain => $_ } } @{$ref}) {
	if (@domlist && $domlist[-1]->{domain}->cn eq $ent->{domain}->cn) {
	    $domlist[-1]->{domain} += $ent->{domain};
	} else {
	    push @domlist, $ent;
	}
    }
    @{$ref} = map { $_->{domain} } sort { $a->{ord} <=> $b->{ord} } @domlist;
}

sub resolve {
    my $host = shift;
    if (my @addrs = gethostbyname($host)) {
	return map { inet_ntoa($_) } @addrs[4 .. $#addrs];
    } else {
	error("$host doesn't resolve");
    }
    return ();
}

sub myip {
    my $host = shift;
    state $ips;
    unless ($ips) {
	$ips = {};
	my $addhost;
	
	if ($config->isset(qw(core my-ip))) {
	    $addhost = 0;
	    foreach my $ip ($config->get(qw(core my-ip))) {
		if ($ip eq '$hostip') {
		    $addhost = 1;
		} else {
		    $ips->{$ip} = 1;
		}
	    }
	} else {
	    $addhost = 1;
	}
	
	if ($addhost) {
	    foreach my $ip (resolve(hostname())) {
		$ips->{$ip} = 1;
	    }
	}
    }
    return $ips->{$host};
}

sub host_ns_ok {
    my $host = shift;
    foreach my $ip (resolve($host)) {
	return 1 if myip($ip);
    }
    return 0
}

sub collect {
    my $aref = shift;
    return unless $config->isset('domain');
    my $err;
    while (my ($k, $v) = each %{$config->get('domain')}) {
	my $dom;
	my $ft;

	if ($config->get(qw(core check-dns))) {
	    my @res = grep { host_ns_ok($_) }
	                   ($k, ($v->{alt} ? @{$v->{alt}} : ()));
	    if (@res) {
		$k = shift @res;
		$v->{alt} = @res ? \@res : undef;
	    } else {
		error("ignoring $k: none of its names resolves to our IP");
		next;
	    }
	}

	if (exists($v->{files})) {
	    if (my $fref = $config->get('files', $v->{files})) {
		$dom = new App::Acmeman::Domain(
		    cn => $k,
		    alt => $v->{alt},
		    postrenew => $v->{postrenew},
		    %{$fref});
	    } else {
		error("files.$v->{files} is referenced from [domain $k], but never declared");
		++$err;
		next;
	    }
	} else {
	    $dom = new App::Acmeman::Domain(
		cn => $k,
		alt => $v->{alt},
 	        postrenew => $v->{postrenew},
		%{$config->get('files', $config->get(qw(core files)))});
	}
	push @$aref, $dom;
    }
    exit(1) if $err;
}

my $setup;
my $time_delta;
my $check_alt_names;

GetOptions("h" => sub {
                    pod2usage(-message => "$progname: $progdescr",
                              -exitstatus => EX_OK);
           },
           "help" => sub {
                    pod2usage(-exitstatus => EX_OK, -verbose => 2);
           },
           "usage" => sub {
                    pod2usage(-exitstatus => EX_OK, -verbose => 0);
           },
           "debug|d+" => \$debug,
           "dry-run|n" => \$dry_run,
	   "stage|s" => sub { $acme_host = 'staging' },
           "force|F" => \$force,
           "time-delta|D=n" => \$time_delta,
	   "setup|S" => \$setup,
	   "alt-names|a" => \$check_alt_names,
	   "config-file|f=s" => \$config_file
) or exit(EX_USAGE);

++$debug if $dry_run;

sub cb_parse_bool {
    my ($k, $vref) = @_;
    my %bt = (
	0 => 0,
	off => 0,
	false => 0,
	no => 0,
	1 => 1,
	on => 1,
	true => 1,
	yes => 1
    );
    my $res = $bt{lc($$vref)};
    if (defined($res)) {
	$$vref = $res;
	return undef;
    }
    return "not a boolean: $$vref";
}

my %syntax = (
    core => {
	section => {
	    postrenew => { array => 1 },
	    rootdir => { default => '/var/www/acme' },
	    files => 1,
	    'time-delta' => { default => 86400 },
	    source => { default => 'apache' },
	    'check-alt-names' => { default => 0, parser => \&cb_parse_bool },
	    'check-dns' => { default => 1, parser => \&cb_parse_bool },
	    'my-ip' => { array => 1 },
            'key-size' => { re => '^\d+$', default => 4096 }
	}
    },
    files => {
	section => {
	    '*' => {
		section => {
		    type => { re => 'single|split', default => 'split' },
		    'certificate-file' => { mandatory => 1 },
		    'key-file' => 1,
		    'ca-file' => 1,
		    argument => 1,
		}
	    }
	}
    },
    domain => {
	section => {
	    '*' => {
		section => {
		    alt => { array => 1 },
		    files => 1,
		    'key-size' => { re => '^\d+$' },
		    postrenew => 0
		}
	    }
	}
    }
);		

sub file_type_fixup {
    my $err;

    $config->set(qw(core files default))
	unless $config->isset(qw(core files));

    unless ($config->isset(qw(files))) {
	if ($config->get(qw(core files)) ne 'default') {
	    error("section files." . $config->get(qw(core files))." not defined");
	    ++$err;
	}
    }

    unless ($config->isset(qw(files default))) {
	$config->set(qw(files default type), 'split');
	$config->set(qw(files default key-file), 
		     '/etc/ssl/acme/$domain/privkey.pem');
	$config->set(qw(files default certificate-file),
		     '/etc/ssl/acme/$domain/cert.pem');
	$config->set(qw(files default ca-file),
		     '/etc/ssl/acme/$domain/ca.pem');
    }
    
    if ($config->isset(qw(files))) {
	while (my ($k, $v) = each %{$config->get(qw(files))}) {
	    if ($v->{type} eq 'single') {
		unless (exists($v->{'certificate-file'})) {
		    error("files.$k.certificate-file not defined");
		    ++$err;
		} else {
		    if (exists($v->{'key-file'})) {
			error("files.$k.key-file ignored");
		    }
		    if (exists($v->{'ca-file'})) {
			error("files.$k.ca-file ignored");
		    }
		}
	    } else {
		unless (exists($v->{'key-file'})) {
		    error("files.$k.key-file not defined");
		    ++$err;
		}
		unless (exists($v->{'certificate-file'})) {
		    error("files.$k.ca-file not defined");
		    ++$err;
		}
	    }
	}
    }

    if (my $files = $config->get(qw(core files))) {
	unless ($config->isset('files', $files)) {
	    error("files.$files is referenced from [core], but never declared");
	    ++$err;
	}
    }
    
    exit(1) if $err;
}

my @domlist;

@select{map { lc } @ARGV} = (1) x @ARGV;

$config = new App::Acmeman::Config($config_file,
				   syntax => \%syntax,
				   defaults => {
				       'core.source' => 'apache',
                                       'core.key-size' => 4096
				   });

if ($config->success) {
    if (my $source = $config->get(qw(core source))) {
	my ($name, @args) = quotewords('\s+', 0, $source);
	my $pack = 'App::Acmeman::Source::' . ucfirst($name);
	my $obj = eval "use $pack; new $pack(\@args);";
	if ($@) {
	    abend(EX_CONFIG, $@);
	}
	$obj->configure($config);
	$config->set(qw(core source), $obj);
    }
    if ($time_delta) {
	$config->set(qw(core time-delta), $time_delta);
    }
    if ($check_alt_names) {
	$config->set(qw(core check-alt-names), $check_alt_names);
    }
    $config->finalize;
}

unless ($config->success) {
    foreach my $err ($config->errors) {
	error($err);
    }
    exit(1);
}

initial_setup if $setup;

file_type_fixup;
#print Dumper([$config]);exit;
collect \@domlist;

debug(1, "nothing to do") unless @domlist;
coalesce \@domlist;

# Check challenge root directory
prep_dir($config->get(qw(core rootdir)).'/file');

# # FIXME Check filename patterns
# abend(EX_CONFIG, "filename patterns not defined")
#     unless (defined($filename_arg) && defined($filename_pattern{cert}));

$challenge = Protocol::ACME::Challenge::LocalFile->new({
    www_root => $config->get(qw(core rootdir))
});

my $renewed = 0;
foreach my $vhost (@domlist) {
    next unless selected_domain($vhost);
    if ($force || domain_cert_expires($vhost)) {
	if (register_domain_certificate($vhost)) {
	    if (my $cmd = $vhost->postrenew) {
		runcmd($cmd);
	    } else {
		$renewed++;
	    }
	}
    }
}

if ($renewed) {
    if ($config->isset(qw(core postrenew))) {
	foreach my $cmd ($config->get(qw(core postrenew))) {
	    runcmd($cmd);
	}
    } else {
     	error("certificates changed, but no postrenew command is defined (core.postrenew)");
    }
}


    

Return to:

Send suggestions and report system problems to the System administrator.